UNIX shell：按字长和 ASCII 顺序对字符串进行排序，忽略大小写

Question

我想使用unix命令按长度对字符串进行排序，然后按ASCII顺序（大小写相等）进行排序。

string = [a-z][A-Z][0-9]

例如：

"A a b B cc ca cd" : 
=> A a b B
=> ca cc cd

"Hello stackoverflow how are you today"
=> are how you
=> Hello today
=> stackoverflow

Answer 1

我写了一个丑陋的（也许）

awk|sort|awk

行来完成这项工作。它也可以在一个 awk 进程中完成，但是，我有点懒，只是采用一种肮脏而快速的方法。

echo yourStr|awk '{
split($0,o); for(x in o) print length(o[x]),o[x]}'|sort -n|awk '!p{printf $2;p=$1;next}$1==p{printf " "$2}$1!=p{printf "\n"$2;p=$1}' 

举个例子：

"Hello stackoverflow how are you today foo bar xoo yoo ooo"

尝试上面的行：

kent$  echo "Hello stackoverflow how are you today foo bar xoo yoo ooo"|awk '{
split($0,o); for(x in o) print length(o[x]),o[x]}'|sort -n|awk '!p{printf $2;p=$1;next}$1==p{printf " "$2}$1!=p{printf "\n"$2;p=$1}'
are bar foo how ooo xoo yoo you
Hello today
stackoverflow     

用你的第一个例子进行测试：

kent$  echo "A a b B cc ca cd" |awk '{
pipe quote> split($0,o); for(x in o) print length(o[x]),o[x]}'|sort -n|awk '!p{printf $2;p=$1;next}$1==p{printf " "$2}$1!=p{printf "\n"$2;p=$1}' 
a A b B
ca cc cd

Answer 2

这是使用

GNU awk

的一种方法。跑步就像：

awk -f script.awk file

script.awk

的内容：

BEGIN {
    IGNORECASE=1
}

{
    for(i=1;i<=NF;i++) {
        a[length($i)][$i]++
    }
}

END {

    for (i in a) {
        b[x++] = i + 0
    }

    n = asort(b)

    for (j=1;j<=n;j++) {

        m = asorti(a[b[j]],c)

        for (k=1;k<=m;k++) {

            for (l=1;l<=a[b[j]][c[k]];l++) {
                r = (r ? r FS : "") c[k]
            }

            s = (s ? s FS : "") r
            r = ""
        }

        print s
        s = ""
    }
}

使用您输入的结果，连接起来：

A a B b
ca cc cd
are how you
Hello today
stackoverflow

或者，这是一句：

awk '{ for(i=1;i<=NF;i++) a[length($i)][$i]++ } END { for (i in a) b[x++] = i + 0; n = asort(b); for (j=1;j<=n;j++) { m = asorti(a[b[j]],c); for (k=1;k<=m;k++) { for (l=1;l<=a[b[j]][c[k]];l++) r = (r ? r FS : "") c[k]; s = (s ? s FS : "") r; r = "" } print s; s="" } }' IGNORECASE=1 file

Answer 3

这是 zsh 的一句话：

zsh -c 'for w ($(<&0)) z[$#w]+="$w "; print -C1 ${(*)z/(#m)*/${${(oi)=MATCH}}}'

给定标准输入上的文本，这会从两个测试用例中产生所需的输出，很大程度上依赖于 IFS 分割和数组扩展标志。