表名作为变量

Question

我正在尝试执行此查询：

declare @tablename varchar(50)
set @tablename = 'test'
select * from @tablename

这会产生以下错误：

消息 1087，第 16 级，状态 1，第 5 行

必须声明表变量“@tablename”。

动态填充表名的正确方法是什么？

Answer 1

对于静态查询，就像您问题中的查询一样，表名和列名需要是静态的。

对于动态查询，您应该动态生成完整的 SQL，并使用 sp_executesql 来执行它。

以下是用于比较不同数据库的相同表之间的数据的脚本示例：

静态查询：

SELECT * FROM [DB_ONE].[dbo].[ACTY]
EXCEPT
SELECT * FROM [DB_TWO].[dbo].[ACTY]

因为我想轻松更改

table

和

schema

的名称，所以我创建了这个动态查询：

declare @schema sysname;
declare @table sysname;
declare @query nvarchar(max);

set @schema = 'dbo'
set @table = 'ACTY'

set @query = '
SELECT * FROM [DB_ONE].' + QUOTENAME(@schema) + '.' + QUOTENAME(@table) + '
EXCEPT
SELECT * FROM [DB_TWO].' + QUOTENAME(@schema) + '.' + QUOTENAME(@table);

EXEC sp_executesql @query

由于动态查询需要考虑的细节很多且难以维护，因此我建议您阅读：动态 SQL 的诅咒与祝福

Answer 2

将您最后的陈述更改为：

EXEC('SELECT * FROM ' + @tablename)

这就是我在存储过程中进行操作的方式。第一个块将声明变量，并根据当前年份和月份名称设置表名称，在本例中为 TEST_2012OCTOBER。然后我检查它是否已存在于数据库中，如果存在则将其删除。然后下一个块将使用 SELECT INTO 语句创建表并使用另一个带参数的表中的记录填充该表。

--DECLARE TABLE NAME VARIABLE DYNAMICALLY
DECLARE @table_name varchar(max)
SET @table_name =
    (SELECT 'TEST_'
            + DATENAME(YEAR,GETDATE())
            + UPPER(DATENAME(MONTH,GETDATE())) )

--DROP THE TABLE IF IT ALREADY EXISTS
IF EXISTS(SELECT name
          FROM sysobjects
          WHERE name = @table_name AND xtype = 'U')

BEGIN
    EXEC('drop table ' +  @table_name)
END

--CREATES TABLE FROM DYNAMIC VARIABLE AND INSERTS ROWS FROM ANOTHER TABLE
EXEC('SELECT * INTO ' + @table_name + ' FROM dbo.MASTER WHERE STATUS_CD = ''A''')

Answer 3

用途：

CREATE PROCEDURE [dbo].[GetByName]
    @TableName NVARCHAR(100)
    AS
BEGIN
    -- SET NOCOUNT ON added to prevent extra result sets from
    -- interfering with SELECT statements.
    SET NOCOUNT ON;
    DECLARE @sSQL nvarchar(500);

    SELECT @sSQL = N'SELECT * FROM' + QUOTENAME(@TableName);

    EXEC sp_executesql @sSQL
END

Answer 4

不能使用表名作为变量。你必须这样做：

DECLARE @sqlCommand varchar(1000)
SET @sqlCommand = 'SELECT * from yourtable'
EXEC (@sqlCommand)

Answer 5

您需要动态生成 SQL 内容：

declare @tablename varchar(50)

set @tablename = 'test'

declare @sql varchar(500)

set @sql = 'select * from ' + @tablename

exec (@sql)

Answer 6

使用

sp_executesql

执行任何 SQL，例如

DECLARE @tbl    sysname,
        @sql    nvarchar(4000),
        @params nvarchar(4000),
        @count  int

DECLARE tblcur CURSOR STATIC LOCAL FOR
   SELECT object_name(id) FROM syscolumns WHERE name = 'LastUpdated'
   ORDER  BY 1
OPEN tblcur

WHILE 1 = 1
BEGIN
   FETCH tblcur INTO @tbl
   IF @@fetch_status <> 0
      BREAK

   SELECT @sql =
   N' SELECT @cnt = COUNT(*) FROM dbo.' + quotename(@tbl) +
   N' WHERE LastUpdated BETWEEN @fromdate AND ' +
   N'                           coalesce(@todate, ''99991231'')'
   SELECT @params = N'@fromdate datetime, ' +
                    N'@todate   datetime = NULL, ' +
                    N'@cnt      int      OUTPUT'
   EXEC sp_executesql @sql, @params, '20060101', @cnt = @count OUTPUT

   PRINT @tbl + ': ' + convert(varchar(10), @count) + ' modified rows.'
END

DEALLOCATE tblcur

Answer 7

需要使用SQL Server动态SQL：

DECLARE @table     NVARCHAR(128),
        @sql       NVARCHAR(MAX);

SET @table = N'tableName';

SET @sql = N'SELECT * FROM ' + @table;

使用 EXEC 执行任意 SQL：

EXEC (@sql)

使用 EXEC sp_executesql 执行任何 SQL：

EXEC sp_executesql @sql;

使用 EXECUTE sp_executesql 执行任何 SQL：

EXECUTE sp_executesql @sql

Answer 8

Declare  @tablename varchar(50) 
set @tablename = 'Your table Name' 
EXEC('select * from ' + @tablename)

Answer 9

希望这段代码有帮助

-- Start process check by counting rows item
SET @Count_Row = 0;
SET @SqlMain = 'SELECT @Cnt = COUNT(*) FROM ['+@Tab_Name+'] WHERE ['+@Col_Name+'] LIKE ''%'+@SearchVal+'%'''
SET @Parm = '@Cnt INT OUTPUT'

EXEC sp_executesql @SqlMain , @Parm , @Cnt = @Count_Row OUT

SET @TotalRow = @TotalRow + @Count_Row

IF  @Count_Row >= 1

    PRINT @Tab_Name+' - '+@Col_Name+' - '+ CONVERT(VARCHAR(10), @Count_Row)

FETCH NEXT FROM CUR_GET_INFO INTO @Tab_Name,@Col_Name

结束

Answer 10

另外，你可以使用这个...

DECLARE @SeqID varchar(150);
DECLARE @TableName varchar(150);
SET @TableName = (Select TableName from Table);
SET @SeqID = 'SELECT NEXT VALUE FOR ' + @TableName + '_Data'
exec (@SeqID)

Answer 11

Declare @fs_e int, @C_Tables CURSOR, @Table varchar(50)

SET @C_Tables = CURSOR FOR
        select name from sysobjects where OBJECTPROPERTY(id, N'IsUserTable') = 1 AND name like 'TR_%'
OPEN @C_Tables
FETCH @C_Tables INTO @Table
    SELECT @fs_e = sdec.fetch_Status FROM sys.dm_exec_cursors(0) as sdec where sdec.name = '@C_Tables'

WHILE ( @fs_e <> -1)
    BEGIN
        exec('Select * from ' + @Table)
        FETCH @C_Tables INTO @Table
        SELECT @fs_e = sdec.fetch_Status FROM sys.dm_exec_cursors(0) as sdec where sdec.name = '@C_Tables'
    END