Arduino timer4自定义PWM问题

Question

我制作了一个很好的代码，可以产生50％占空比的快速PWM，我可以用电位计改变频率。它输出直通和反向通道，有一些死区时间。我正在使用Arduino Micro aka ATmega32U4。代码实际上是“Atmel”代码。代码工作正常，直到我关闭Arduino Micro然后重新启动。

我已经编写了代码和寄存器，因此频率可以在10kHz到100kHz之间变化。但电源开/关后频率从5kHz变为50kHz。发生这种情况后，我必须使用Arduino IDE再次对电路板进行编程，以使其正常工作。电源开/关后再次发生变化。我很确定其中一个寄存器被“Arduino硬件抽象层”覆盖，或者我们应该命名它。我还没有读出所有寄存器，所以我不知道哪一个被覆盖了。我想这是预分频器。我该如何防止这种情况发生？我应该把寄存器内容写在别的地方吗？或者我应该写几次以确定吗？无论如何，为什么或如何发生这种情况？

这是代码：

#define OSC1  5
#define OSC2  13

uint8_t read_reg1;
uint8_t read_reg2;
int pot, freq; 

void setup() {
  pinMode(OSC1, OUTPUT); 
  pinMode(OSC2, OUTPUT); 
  Serial.begin(9600);

  cli();  // disable global interrupts

  TCCR4A=0; // clear register
  TCCR4B=0x06; // configure prescaler to 64 (CK = CLK / 64 = 1.5 MHz)
  TCCR4C=0;
  TCCR4D=0; // select Fast PWM operation (0 << WGM41)|(0 << WGM40)
  PLLFRQ=(PLLFRQ&0xCF)|0x30; // select clock source and frequency
  OCR4C=150; // select PWM frequency
  OCR4A=150/2; // set duty cycle
  DT4 = 0x55; // set dead times. DT = (1 / 48Mhz) * 0...15

  // enable interrupt on timer4 overflow
  TIMSK4|=(1 << TOIE4);

  // This register write has to be after others. Otherwise the PWM generation will not work. I do not know why. 
  TCCR4A=0x42; // COM4A1..0 = 01, OC4A and !OC4A connected. PWM4A = 1 (activate channel A PWM output)

  sei(); // enable global interrupts
}

void loop() {
  //cli();
  pot = analogRead(A0);
  freq = map(pot, 0, 1023, 14, 166);
  //sei();
  /*
  Serial.print("Pot value: ");
  Serial.print(pot);
  Serial.print("\tFreq value: ");  
  Serial.println(1500000/freq);
  */

}

ISR(TIMER4_OVF_vect){
  OCR4C = freq;
  OCR4A = freq / 2; 
}

Answer 1

我不确定为什么你在编程后会有不同的行为，但Arduino Micro使用的引导程序（Caterina）在运行后不会执行完全重置，因此引导加载程序对AVR寄存器的更改通常是可见的。用户的草图。

我能够通过删除修改PLLFRQ的行来解决问题。以下是代码的简化版本，总是产生3.31 kHz PWM：

void setup()
{
  pinMode(5, OUTPUT); 
  pinMode(13, OUTPUT);

  TCCR4A = 0;
  TCCR4B = 0x06; // configure prescaler to 64 (CK = CLK / 64 = 1.5 MHz)
  TCCR4C = 0;
  TCCR4D = 0; // select Fast PWM operation (0 << WGM41)|(0 << WGM40)
  OCR4C = 150; // select PWM frequency
  OCR4A = 150 / 2; // set duty cycle
  DT4 = 0x55; // set dead times. DT = (1 / 48Mhz) * 0...15

  // This register write has to be after others.
  // Otherwise the PWM generation will not work. I do not know why. 
  // COM4A1..0 = 01, OC4A and !OC4A connected.
  // PWM4A = 1 (activate channel A PWM output)
  TCCR4A = 0x42;
}

void loop()
{
}

搞乱PLL后分频器并不是一个好主意，因为它可能会影响使用定时器的所有其他Arduino库，包括USB堆栈。