DAX按测量结果分组

Question

需要一些帮助，在这里使用DAX为PowerBI中的视觉分组测量结果。我有一个表格，显示某些客户的所有访问（访问表）。我有一个计算每天访问次数的度量，我有一个日期切片器（访问日）。这项措施的结果通常在1到10之间。我试图查看每年客户访问的频率。如果他们有

1 = single visit
3 or more visits = returning customer
7 or more visits = frequent customer.

我试图使用饼图/圆环图来显示我的客户在一年内的细分。我相信这是可能的，但我错过了一些东西。任何帮助，将不胜感激！

Customer_id          Visit_date      Purchase_total   

以上是访问表的示例。还有一项措施使用DAX获得每日总访问量。 （有些客户在某一天[visits_day]会多次来访。）

Answer 1

通过饼图中的度量进行分组有点棘手，因为您无法将度量放入例如“图例”框，如果您希望根据切片器选择更改分组，则无法使用计算列。

这是一个可能的解决方法：

首先，为您的类别桶创建一个新的Buckets表。

Bucket
------
single visit
returning customer
frequent customer

这个Buckets[Bucket]专栏是你在Legend部分中使用的。

对于“值”部分，我们需要一个新的度量：

Count of Visits =
VAR Summary =
    SUMMARIZE (
        Visits,
        Visits[Customer_id],
        "Bucket", SWITCH (
            TRUE (),
            COUNTROWS ( Visits ) >= 7, "frequent customer",
            COUNTROWS ( Visits ) >= 2, "returning customer",
            COUNTROWS ( Visits ) = 1, "single visit"
        )
    )
RETURN
    SUMX ( Summary, IF ( [Bucket] = SELECTEDVALUE ( Bucket[Bucket] ), 1, 0 ) )

此度量总结了当前的Visits表（应用了任何切片器过滤），将每个客户根据他们在您选择的日期范围内访问过的次数放入三个桶中的一个。然后我们通过仅为汇总表中的客户添加1来计算有多少客户属于当前饼图部分，该汇总表的桶与当前饼图桶匹配（否则为0）。

---

注意：此度量将客户分类为您选择的日期。如果您不关心这一点并且只需要计算固定时间段的类别（即您不希望日期切片器更改它们所属的桶），那么您可以使用计算列而不是需要创建一个新表。