在查询中调用事实

Question

这是我的代码：

sentence([['o'],['m','e','n','i','n','o'],['a','l','e','g','r','e']]).

lastWord(X,[X]).
lastWord(X,[_|Z]) :- lastWord(X,Z).

如果我尝试lastWord(X,[1,2,3]).甚至lastWord(X,[['o'],['m','e','n','i','n','o'],['a','l','e','g','r','e']]).我得到我想要的东西（当然，这是列表的最后一个元素（在例子中，3和['a','l','e','g','r','e']）。

但如果我尝试lastWord(X, sentence).或lastWord(X, sentence(Y)).我得到false。

如何在lastWord中“调用”已定义的列表（在本例中为“sentence”）？

Answer 1

Prolog不是一种功能语言。因此，在诸如lastWord(X, sentence)或lastWord(X, sentence(Y))这样的目标中，不会用sentence谓词的论证取代sentence(Y)或sentence/1。尝试改为：

?- sentence(List), lastWord(Last, List).
List = [[o], [m, e, n, i, n, o], [a, l, e, g, r, e]],
Last = [a, l, e, g, r, e] ;
false.

请注意，查询还有一个虚假的选择点。您可以通过重写谓词lastWord/2的定义来消除它。通常名为last/2的类似谓词通常可从库中获得：

last([Head| Tail], Last) :-
    last(Tail, Head, Last).

last([], Last, Last).
last([Head| Tail], _, Last) :-
    last(Tail, Head, Last).

注意不同的参数顺序（Prolog编码指南建议在输出参数之前有输入参数）。改为使用这个谓词：

?- sentence(List), last(List, Last).
List = [[o], [m, e, n, i, n, o], [a, l, e, g, r, e]],
Last = [a, l, e, g, r, e].