在ESP8266上读取c中的const *时发生崩溃

问题描述 投票：0回答：2

我正在建立一个系统，通过SoftwareSerial从Arduino Uno读取传感器值，并通过MQTT发布。但是，我认为我面临的问题更为笼统，我必须承认我是新手。

我正在读取数据，并将其拆分为两个在我的程序顶部定义的const *变量。

当我读回已经从串行连接解析的已保存的“数据”和“主题”变量时，我只获得垃圾输出，并且通常是重启设备的崩溃。

它在read-from-serial函数中成功打印出来，但以后无法正确读取。它可以与数据的保存方式有关吗？我可以为变量显式分配一些内存吗？

我正在使用ESP8266（ESP07）芯片，它具有较低的波特率和适当的电压供应。它看起来运行良好且稳定。

#include <StringSplitter.h>
#include <PubSubClient.h>
#include <ESP8266WiFi.h>
#include <time.h>

//const char* ssid = "xxxx";
//const char* password =  "xxxx";
const char* ssid = "xxxx";
const char* password =  "xxxx";
const char* mqttServer = "xxxx;
const int mqttPort = xxxx;
const char* mqttUser = "xxxx";
const char* mqttPassword = "xxxx";
int timezone = 1;
int dst = 0;

数据存储在这里：

char* data;
char* topic;
boolean newData = false;
boolean unpublishedData = false;

WiFiClient espClient;
PubSubClient client(espClient);

void setup() {

  Serial.begin(19200);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println("Connecting to WiFi..");
  }
  Serial.println("Connected to the WiFi network");
  configTime(timezone * 3600, dst * 0, "pool.ntp.org", "time.nist.gov");


  client.setServer(mqttServer, mqttPort);
  client.setCallback(callback);

  while (!client.connected()) {
    Serial.println("Connecting to MQTT...");

    if (client.connect("ESP8266Client", mqttUser, mqttPassword )) {

      Serial.println("connected");

    } else {

      Serial.print("failed with state ");
      Serial.print(client.state());
      delay(2000);

    }
    // wait and determine if we have a valid time from the network.
    time_t now = time(nullptr);
    Serial.print("Waiting for network time.");
    while (now <= 1500000000) {
      Serial.print(".");
      delay(300); // allow a few seconds to connect to network time.
      now = time(nullptr);
    }
  }
  Serial.println("");

  time_t now = time(nullptr);
  Serial.println(ctime(&now));

  String datatext = "val: ";
  String timetext = ", time: ";
  String dataToBeSent = "test";
  String timeToBeSent = ctime(&now);

  String publishString = datatext + dataToBeSent + timetext + timeToBeSent;
  Serial.println("Attempting to publish: " + publishString);
  client.publish("trykk/sensor0", (char*) publishString.c_str());
  client.subscribe("trykk/sensor0");

}

void callback(char* topic, byte* payload, unsigned int length) {

  Serial.print("Message arrived in topic: ");
  Serial.println(topic);

  Serial.print("Message:");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }

  Serial.println();
  Serial.println("-----------------------");

}

void loop() {
  client.loop();
  recvWithStartEndMarkers();
  showNewData();
  publishReceived();
}

void publishReceived() {
  if (unpublishedData) {
    Serial.println("Hello from inside the publisher loop!");
    time_t now = time(nullptr);
    char* timeNow = ctime(&now);

它失败了，阅读数据：

    char publishText[30]; //TODO: make it JSON
    strcpy( publishText, data );
    strcat( publishText, " " );
    strcat( publishText, timeNow );

    Serial.print("publishText: ");
    Serial.println(publishText);
    Serial.print("topic: "); 
    Serial.println(topic);
    client.publish(topic, publishText);
    client.subscribe(topic);
    unpublishedData = false;
  } else if (!data) {
    Serial.println("No data saved to array.");
  } else if (!topic) {
    Serial.println("No topic saved to array.");
  }
}

void recvWithStartEndMarkers() {
  int numChars = 32;
  char receivedChars[numChars];
  static boolean recvInProgress = false;
  static byte ndx = 0;
  char startMarker = '<';
  char endMarker = '>';
  char rc;

  if (Serial.available() > 0) {
    Serial.println("Hello from inside the receive loop!");
    delay(100);
    while (Serial.available() > 0 && newData == false) {
      rc = Serial.read();
      Serial.println("Reading from data line.");

      if (recvInProgress == true) {
        if (rc != endMarker) {
          receivedChars[ndx] = rc;
          ndx++;
          if (ndx >= numChars) {
            ndx = numChars - 1;
          }
        }
        else {
          Serial.println("Found the end marker.");
          receivedChars[ndx] = '\0'; // terminate the string
          recvInProgress = false;
          ndx = 0;
          newData = true;
          unpublishedData = true;

这部分正确地将值打印给我：

          //Split the string
          Serial.print("ESP debug: read: ");
          Serial.println(receivedChars);
          const char s[2] = ":";
          *data = strtok(receivedChars, s);
          Serial.print(data);
          Serial.print(" ");
          *topic = strtok(NULL, s);
          Serial.println(topic);
        }
      }

      else if (rc == startMarker) {
        recvInProgress = true;
        Serial.println("Found start marker");
      }
    }
  }
}

//This is gutted as it gave me problems reading the variables
void showNewData() {
  if (newData == true) {
    Serial.print("This just in ... ");
    Serial.print("Topic: ");
    Serial.print("stuff");
    Serial.print(", data: ");
    Serial.println("more stuff");
    newData = false;
  }
}
c arduino esp8266 software-serial
2个回答
2
投票

在确定将strtok的结果分配给data之后，如bruno的回答所示，还有另一个可能导致崩溃的错误。

你的函数loop()首先调用recvWithStartEndMarkers()，然后调用publishReceived()。

void loop() {
  client.loop();
  recvWithStartEndMarkers();
  showNewData();
  publishReceived();
}

在函数recvWithStartEndMarkers中，您将一些数据读入本地数组receivedChars，将其输入strtok并将从strtok返回的指针写入全局变量data。

void recvWithStartEndMarkers() {
  int numChars = 32;
  char receivedChars[numChars]; /* this is a local variable with automatic storage */
  /* ... */

    while (Serial.available() > 0 && newData == false) {
      /* ... */
          receivedChars[ndx] = rc;
          ndx++;
          if (ndx >= numChars) {
            ndx = numChars - 1;
          }
          /* ... */
          receivedChars[ndx] = '\0'; // terminate the string
          /* Now there is a terminated string in the local variable */
          /* ... */

          //Split the string
          /* ... */
          const char s[2] = ":";
          data = strtok(receivedChars, s); /* strtok modifies the input in receivedChars and returns a pointer to parts of this array. */ 
          /* ... */
}

离开函数后，receivedChars的内存不再有效。这意味着data将指向堆栈上的此无效内存。

之后，您希望在函数data中访问全局变量publishReceived()。访问此内存是未指定的行为。你可能仍然得到数据，你可能得到别的东西或你的程序可能会崩溃。

void publishReceived() {
  /* ... */
    char publishText[30]; //TODO: make it JSON
    strcpy( publishText, data ); /* This will try to copy whatever is now in the memory that was part of receivedChars inside recvWithStartEndMarkers() but may now contain something else, e.g. local data of function publishReceived(). */
  /* ... */

要解决这个问题，你可以在strdup中使用recvWithStartEndMarkers()：

data = strtok(receivedChars, s);
if(data != NULL) data = strdup(data);

然后，当你不再需要数据或再次调用free(data)之前，你必须在某处使用recvWithStartEndMarkers()。

或者使data成为一个数组并在strncpy中使用recvWithStartEndMarkers()。

5
投票

从您的代码：

char* data;
...
*data = strtok(receivedChars, s);

strtok返回一个char*，但你做*data = strtok(...)而数据本身是一个（非初始化的）char *，这是不一致的，你有第一次“机会”发生崩溃，因为你在随机地址写。

如果您没有崩溃并且您的程序可以继续，则数据不会自行修改并保持未初始化状态。

在

strcpy( publishText, data );
...
Serial.print(data);

当你使用数据作为char*做Serial.print(data);和strcpy( publishText, data );时，你会从一个随机（当然也是无效的）地址中读取，从而导致崩溃。

要纠正，只需用*data = strtok(receivedChars, s);替换data = strtok(receivedChars, s);

最新问题
© www.soinside.com 2019 - 2024. All rights reserved.