React Native CLI Xcode 在更新到 XCode 15 和 iOS 17 后构建（模拟器）失败

Question

在我的 MAC Air m2 和 iOS 17 上安装 XCode 15 后，我尝试使用 Iphone 15 Rosetta 模拟器构建 React 本机应用程序，但出现错误，它在 iOS 16.4 Rosetta 构建中表现良好。 我尝试了 pod install --repo-update 我尝试使用 iOS 16.2 Rosetta 模拟器进行构建，但遇到了同样的错误。 但是，如果我在 FIRFirestoneSettings.mm 中进行更改，它就可以正常工作 ABSL_CONST_INIT extern "C" const int64_t kFIRFirestoreCacheSizeUnlimited = 设置::CacheSizeUnlimited; 到 extern "C" const int64_t kFIRFirestoreCacheSizeUnlimited = 设置::CacheSizeUnlimited; 参考：https://github.com/dpa99c/cordova-plugin-firebasex/issues/830#issuecomment-1727338004 这是文件 FIRFirestoreSettings.mm 的代码

/*
 * Copyright 2017 Google LLC
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

#import "FIRFirestoreSettings.h"

#include "Firestore/core/src/api/settings.h"
#include "Firestore/core/src/util/exception.h"
#include "Firestore/core/src/util/string_apple.h"
#include "absl/base/attributes.h"
#include "absl/memory/memory.h"

NS_ASSUME_NONNULL_BEGIN

namespace api = firebase::firestore::api;
using api::Settings;
using firebase::firestore::util::MakeString;
using firebase::firestore::util::ThrowInvalidArgument;

// Public constant
ABSL_CONST_INIT extern "C" const int64_t kFIRFirestoreCacheSizeUnlimited =
    Settings::CacheSizeUnlimited;

@implementation FIRFirestoreSettings

- (instancetype)init {
  if (self = [super init]) {
    _host = [NSString stringWithUTF8String:Settings::DefaultHost];
    _sslEnabled = Settings::DefaultSslEnabled;
    _dispatchQueue = dispatch_get_main_queue();
    _persistenceEnabled = Settings::DefaultPersistenceEnabled;
    _cacheSizeBytes = Settings::DefaultCacheSizeBytes;
  }
  return self;
}

- (BOOL)isEqual:(id)other {
  if (self == other) {
    return YES;
  } else if (![other isKindOfClass:[FIRFirestoreSettings class]]) {
    return NO;
  }

  FIRFirestoreSettings *otherSettings = (FIRFirestoreSettings *)other;
  return [self.host isEqual:otherSettings.host] &&
         self.isSSLEnabled == otherSettings.isSSLEnabled &&
         self.dispatchQueue == otherSettings.dispatchQueue &&
         self.isPersistenceEnabled == otherSettings.isPersistenceEnabled &&
         self.cacheSizeBytes == otherSettings.cacheSizeBytes;
}

- (NSUInteger)hash {
  NSUInteger result = [self.host hash];
  result = 31 * result + (self.isSSLEnabled ? 1231 : 1237);
  // Ignore the dispatchQueue to avoid having to deal with sizeof(dispatch_queue_t).
  result = 31 * result + (self.isPersistenceEnabled ? 1231 : 1237);
  result = 31 * result + (NSUInteger)self.cacheSizeBytes;
  return result;
}

- (id)copyWithZone:(__unused NSZone *_Nullable)zone {
  FIRFirestoreSettings *copy = [[FIRFirestoreSettings alloc] init];
  copy.host = _host;
  copy.sslEnabled = _sslEnabled;
  copy.dispatchQueue = _dispatchQueue;
  copy.persistenceEnabled = _persistenceEnabled;
  copy.cacheSizeBytes = _cacheSizeBytes;
  return copy;
}

- (void)setHost:(NSString *)host {
  if (!host) {
    ThrowInvalidArgument("Host setting may not be nil. You should generally just use the default "
                         "value (which is %s)",
                         Settings::DefaultHost);
  }
  _host = [host mutableCopy];
}

- (void)setDispatchQueue:(dispatch_queue_t)dispatchQueue {
  if (!dispatchQueue) {
    ThrowInvalidArgument(
        "Dispatch queue setting may not be nil. Create a new dispatch queue with "
        "dispatch_queue_create(\"com.example.MyQueue\", NULL) or just use the default (which is "
        "the main queue, returned from dispatch_get_main_queue())");
  }
  _dispatchQueue = dispatchQueue;
}

- (void)setCacheSizeBytes:(int64_t)cacheSizeBytes {
  if (cacheSizeBytes != kFIRFirestoreCacheSizeUnlimited &&
      cacheSizeBytes < Settings::MinimumCacheSizeBytes) {
    ThrowInvalidArgument("Cache size must be set to at least %s bytes",
                         Settings::MinimumCacheSizeBytes);
  }
  _cacheSizeBytes = cacheSizeBytes;
}

- (BOOL)isUsingDefaultHost {
  NSString *defaultHost = [NSString stringWithUTF8String:Settings::DefaultHost];
  return [self.host isEqualToString:defaultHost];
}

- (Settings)internalSettings {
  Settings settings;
  settings.set_host(MakeString(_host));
  settings.set_ssl_enabled(_sslEnabled);
  settings.set_persistence_enabled(_persistenceEnabled);
  settings.set_cache_size_bytes(_cacheSizeBytes);
  return settings;
}

@end

NS_ASSUME_NONNULL_END

Answer 1

我想此时唯一的解决方法是更改 FIRFirestoneSettings.mm ABSL_CONST_INIT extern "C" const int64_t kFIRFirestoreCacheSizeUnlimited = Settings::CacheSizeUnlimited; 到 extern "C" const int64_t kFIRFirestoreCacheSizeUnlimited = 设置::CacheSizeUnlimited; 参考：https://github.com/dpa99c/cordova-plugin-firebasex/issues/830#issuecomment-1727338004