Delphi - 如何获取 Windows 驱动器的总磁盘空间？

Question

我需要获取Delphi程序中的总磁盘空间。

Answer 1

使用 DiskSize 和 DiskFree 函数解决此问题。 ComboBox1 包含驱动器字母列表。

var
  Disk: Integer;
...
procedure TForm1.Button1Click(Sender: TObject);
var
  Total, Free: LongInt;
begin
  Total:=DiskSize(Disk) div 1024;
  Free:=DiskFree(Disk) div 1024;
  Gauge1.MaxValue:=Total;
  Gauge1.Progress:=Free;
  Label1.Caption:='Total size - '+IntToStr(Total);
  Label2.Caption:='Free - '+IntToStr(Free);
end;

procedure TForm1.ComboBox1Change(Sender: TObject);
begin
  Disk:=ComboBox1.ItemIndex+1;
end;

Answer 2

这里您还有另一个选择，使用

Win32_LogicalDisk

WMI 类

{$APPTYPE CONSOLE}

uses
  SysUtils,
  ActiveX,
  ComObj,
  Variants;

procedure  GetWin32_LogicalDiskSize(const drive: string);
const
  WbemUser            ='';
  WbemPassword        ='';
  WbemComputer        ='localhost';
  wbemFlagForwardOnly = $00000020;
var
  FSWbemLocator : OLEVariant;
  FWMIService   : OLEVariant;
  FWbemObjectSet: OLEVariant;
  FWbemObject   : OLEVariant;
  oEnum         : IEnumvariant;
  iValue        : LongWord;
begin;
  FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  FWMIService   := FSWbemLocator.ConnectServer(WbemComputer, 'root\CIMV2', WbemUser, WbemPassword);
  FWbemObjectSet:= FWMIService.ExecQuery(Format('SELECT * FROM Win32_LogicalDisk Where Caption=%s',[QuotedStr(drive)]),'WQL',wbemFlagForwardOnly);
  oEnum         := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
  if oEnum.Next(1, FWbemObject, iValue) = 0 then
  begin
    Writeln(Format('FreeSpace  %s Bytes',[FormatFloat('#,',FWbemObject.FreeSpace)]));// Uint64
    Writeln(Format('Size       %s Bytes',[FormatFloat('#,',FWbemObject.Size)]));// Uint64
    FWbemObject:=Unassigned;
  end;
end;


begin
 try
    CoInitialize(nil);
    try
      GetWin32_LogicalDiskSize('C:');
    finally
      CoUninitialize;
    end;
 except
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.

Answer 3

有些人可能会发现这很有用 - 它会根据卷的 DeviceID 为您提供总磁盘空间和可用磁盘空间。它也像 RRUZ 的答案一样使用 WMI，但它与 DeviceID 一起使用，因此它具有相同的优点+它也可以与未映射的设备和驱动程序（或映射到路径）一起使用。

procedure DiskSizesFromVolumeDeviceID(deviceID:string);
var
  WMIServices : ISWbemServices;
  Root        : ISWbemObjectSet;
  Item: Variant;
  i: Integer;
  Cap:TCap;
begin
  try
  WMIServices := CoSWbemLocator.Create.ConnectServer('.', 'root\cimv2','', '', '', '', 0,     nil);
  Root  := WMIServices.ExecQuery(Format('SELECT Capacity, FreeSpace FROM Win32_Volume     WHERE DeviceID="%s"', [StringReplace(deviceID, '\', '\\', [rfReplaceAll])]),'WQL', 0, nil);
  for i := 0 to Root.Count - 1 do
  begin
    Item := Root.ItemIndex(i);

    TotalSpace := ( Item.Capacity);
    FreeSpace := (Item.FreeSpace);
  End;
end;

Answer 4

使用此代码的最佳方法：

var
    lpFreeBytesAvailableToCaller, 
    lpTotalNumberOfBytes, 
    lpTotalNumberOfFreeBytes : TLargeInteger; // Int64;
begin
   ...
   GetDiskFreeSpaceExA(PChar(path_to_dir), lpFreeBytesAvailableToCaller, lpTotalNumberOfBytes, @lpTotalNumberOfFreeBytes);
   ...
end;

Answer 5

只是想插话分享我最终根据我在接受的答案中收集的内容实施的解决方案：

function GetDriveCapacity(const Drive: Integer): Int64;
begin
  Result:= DiskSize(Drive);
end;

function GetDriveSpaceFree(const Drive: Integer): Int64;
begin
  Result:= DiskFree(Drive);
end;

function GetDriveSpaceUsed(const Drive: Integer): Int64;
begin
  Result:= GetDriveCapacity(Drive) - GetDriveSpaceFree(Drive);
end;

function GetDriveSpaceUsedPct(const Drive: Integer): Single;
var
  U, C: Int64;
begin
  try
    U:= GetDriveSpaceUsed(Drive);
    C:= GetDriveCapacity(Drive);
    Result:= (U / C) * 100;
  except
    Result:= -1;
  end;
end;

这里一切的核心都从

GetDriveSpaceUsedPct

开始。这将返回 1 到 100 之间的浮点数，表示磁盘上可用空间的百分比。

注意：在使用

DiskSize

参数时，请参阅

DiskFree

和

Drive

的文档。

用途：

procedure TfrmJDSSysMonGaugesTest.TmrTimer(Sender: TObject);
var
  Perc: Double;
begin
  //C Drive Usage
  Perc:= GetDriveSpaceUsedPct(3);
  ...
  //D Drive Usage
  Perc:= GetDriveSpaceUsedPct(4);
  ...
end;