C ++ ZBar cmake错误'找不到文件'，包括

Question

我在C ++脚本中包含ZBar时遇到问题。我已经尝试通过CMakelists.txt添加它：

cmake_minimum_required(VERSION 2.8.12)
project( Barcode-cpp )
find_package( OpenCV REQUIRED )
include_directories( ${OpenCV_INCLUDE_DIRS} ${ZBARCV_SOURCE_DIR} )
set(CMAKE_MODULE_PATH ${ZBARCV_SOURCE_DIRS})
add_compile_options(-std=c++11)
add_library( src
        src/VideoVeed.h
        src/VideoVeed.cpp
        src/Crop.h
        src/Crop.cpp
        src/Barcodes.h
        src/Barcodes.cpp
)
add_executable( program
            program/main.cpp
)
target_link_libraries( program src ${OpenCV_LIBS} ${ZBAR_LIBRARIES} zbar )

我在Mac上。我查看了一下，然后将zbar.h文件放在了应该位于的/usr/local/include/中。

我这样包含：#include <zbar.h>

我希望有人能够帮助我。预先感谢！

编辑：

完整错误日志：

/Users/mathijs/Documents/Barcode-cpp/src/Barcodes.h:7:10: fatal error: 'zbar.h' file not found
#include <zbar.h>
         ^~~~~~~~
1 error generated.
make[2]: *** [CMakeFiles/src.dir/src/VideoVeed.cpp.o] Error 1
make[1]: *** [CMakeFiles/src.dir/all] Error 2
make: *** [all] Error 2

Answer 1

我刚刚检查过； ZBar的Brew软件包包括packageconfig文件（zbar.pc）

这意味着您可以使用现代的CMake工具代替货物培训：

cmake_minimum_required(VERSION 3.8)
project( Barcode-cpp )
find_package( OpenCV REQUIRED )
include_directories(${OpenCV_INCLUDE_DIRS})
set(CMAKE_CXX_STANDARD 11)

add_library( src
        src/VideoVeed.h
        src/VideoVeed.cpp
        src/Crop.h
        src/Crop.cpp
        src/Barcodes.h
        src/Barcodes.cpp
)
add_executable( program
            program/main.cpp
)
target_link_libraries(program src ${OpenCV_LIBS})

find_package(PkgConfig REQUIRED)
pkg_check_modules(ZBar REQUIRED IMPORTED_TARGET zbar)

target_link_libraries(program PkgConfig::ZBar)

pkg_check_modules将读取zbar.pc文件并生成一个名为IMPORTED的PkgConfig::ZBar目标，该目标将自动设置program的包含路径和链接器路径。