如何创建一个二维自上而下的移动系统，在处理过程中可以按住两个键进行移动？

Question

所以，我试图自学如何制作小型游戏，我想制作一款自上而下的游戏。我对编码总体来说还是新手，所以我的代码不是最好的。我正在尝试创建一个移动系统，但是当我按住两个键时，代码只会使用最后一次按下的键。我通过检查它们是否使用 print(key) 注册来确认这一点；声明。

到目前为止，我尝试使用通过 keyPressed() 和 keyReleased() 方法打开和关闭的布尔值。我还在玩家类中尝试过这个，目前它只是一个矩形，其 x 和 y 变量在按下的键上更新加深。当前的运动代码来自我在处理过程中制作的乒乓球游戏的修改版本，其中运动确实有效。下面附上我的代码。有人有什么建议吗？

boolean gameStart = false;

boolean up = false;
boolean down = false;
boolean left = false;
boolean right = false;
 
Player p;

void setup(){
  size(1000,1000);
  p = new Player();
}

void draw(){
  if(!gameStart){
    menu();
  }
  else{
    game();
  }
}

void menu(){
  background(0);
  textSize(90);
  
  stroke(110);
  strokeWeight(10);
  fill(0);
  rectMode(CENTER);
  rect(500,600,300,150);
  fill(255);
  text("GAME",385,300);
  text("PLAY",400,625);
  if(mousePressed && ((mouseX > 350 && mouseX < 650) && (mouseY > 525 && mouseY < 675))){
    gameStart = true;
    noStroke();
  }
}

void keyPressed(){
  if(key == 'w'){
    up = true;
  }
  else if(key == 's'){
    down = true;
  }
  else if(key == 'd'){
    right = true;
  }
  else if(key == 'a'){
    left = true;
  }
}

void keyReleased(){
  if(key == 'w'){
    up = false;
  }
  else if(key == 's'){
    down = false;
  }
  else if(key == 'd'){
    right = false;
  }
  else if(key == 'a'){
    left = false;
  }
}

void game(){
  background(0);
  p.update();
  p.render();
}

class Player{
  
  float x = 500;
  float y = 500;
  
  
    
  
  void player(float x, float y){
    this.x = x;
    this.y = y;
  }
  
  void update(){
    if(up){
      y-=7.5;
    }
    else if(down){
      y+=7.5;
    }
    else if(left){
      x-=7.5;
    }
    else if(right){
      x+=7.5;
    }
  }
  void render(){
    fill(255,0,0);
    rect(x,y,100,100);
  }
}
  
  

Answer 1

以下源代码将在同时按下两个键时沿对角线移动一个矩形。布尔数组用于跟踪按键。

boolean[] keyDwn = new boolean[4];

final int _keyA = 65;
final int _keyW = 87;
final int _keyS = 83;
final int _keyD = 68;

int x, y;

void setup() {
  size(600, 600);
  surface.setTitle("A=up : S=left : W=down : D=right : AS=diagonal : WD=diagonal ");
  // init values
  keyDwn[0] = false;
  keyDwn[1] = false;
  keyDwn[2] = false;
  keyDwn[3] = false;
  fill(0, 0, 255); // color for rectangle
  x = width/2;  
  y = height/2; 
}

void draw() {
  background(209);
  moveObj();
  rect(x, y, 100, 100);
}

void keyPressed() {
  if (keyCode == _keyA) {
    keyDwn[0] = true;
    println("keyA pressed = ", keyCode);
  }
  if (keyCode == _keyW) {
    keyDwn[1] = true;
    println("keyW pressed = ", keyCode);
  }
  if (keyCode == _keyS) {
    keyDwn[2] = true;
    println("keyS pressed = ", keyCode);
  }
  if (keyCode == _keyD) {
    keyDwn[3] = true;
    println("keyD pressed = ", keyCode);
  }
}

void keyReleased() {
  if (keyCode == _keyA) {
    keyDwn[0] = false;
  }
  if (keyCode == _keyW) {
    keyDwn[1] = false;
  }
  if (keyCode == _keyS) {
    keyDwn[2] = false;
  }
  if (keyCode == _keyD) {
    keyDwn[3] = false;
  }
}

void moveObj() {
  if (keyDwn[0]) y -= 3;
  if (keyDwn[1]) y += 3;
  if (keyDwn[2]) x -= 5;
  if (keyDwn[3]) x += 5;
}