PLSQL 将一个本地集合传递到一个流水线函数中。

Question

我需要将一个本地定义的表类型传递给一个函数，而这个函数是一个流水线函数，返回另一个本地定义的表类型。

这里是数据样本。

create table my_tab
(i NUMBER,
 n VARCHAR2(30));

 insert into my_tab values (1, 'Peter');
 insert into my_tab values (2, 'Dakshesh');
 insert into my_tab values (1, 'Maggie');
 insert into my_tab values (3, 'Madhu');
 commit;

我的代码是：

CREATE OR REPLACE PACKAGE my_pkg IS
    TYPE t_col IS RECORD(
    i NUMBER,
    n VARCHAR2(30));
    TYPE t_nested_table IS TABLE OF t_col;
    TYPE t_number IS TABLE OF NUMBER;
    FUNCTION iterate_table RETURN t_number PIPELINED;
    FUNCTION return_table(in_t_num t_number) RETURN t_nested_table PIPELINED;
     g_number t_number ;
     g_nested_number t_nested_table ;
  END my_pkg;
  /

Body:

 CREATE OR REPLACE PACKAGE BODY my_pkg IS
    FUNCTION iterate_table RETURN t_number PIPELINED IS
    BEGIN
      IF ( (g_number IS NOT NULL) AND (g_number.EXISTS (1)))
      THEN
         FOR i IN 1 .. g_number.COUNT
         LOOP
            IF g_number (i) IS NOT NULL
            THEN
               PIPE ROW (g_number (i));
            END IF;
         END LOOP;
      END IF;
      RETURN;
   EXCEPTION
      WHEN OTHERS
      THEN
         RAISE;
   END iterate_table;

   FUNCTION return_table(in_t_num t_number) RETURN t_nested_table PIPELINED IS
      l_row t_nested_table ;
      CURSOR cur_test IS
          select mt.i, mt.n 
          from my_tab mt, TABLE(iterate_table ) tab
          where mt.i = tab.column_value;
     BEGIN
         OPEN cur_test;
         FETCH cur_test BULK COLLECT into l_row;
         CLOSE cur_test;
         FOR i IN 1..l_row.COUNT
         LOOP
             PIPE ROW(l_row(i));
         END LOOP;
         RETURN;
     END return_table;
 END my_pkg;
 /

现在这段代码编译成功了，当我尝试像调用流水线函数一样调用它时，它给出了错误信息-

select * from table(my_pkg.return_table(my_pkg.t_number(1)));

错误

ORA-00902: invalid datatype
00902. 00000 -  "invalid datatype"
*Cause: 
*Action:
Error at Line: 14 Column: 41

该代码的两个先决条件是------。

1. 所有的集合都应该是本地定义的。

2. 函数应该是管道式的。

我没有收到任何关于表的错误信息，而且它是一个单表，所以没有外键约束。

Answer 1

这在oracle 11中是不可能的。我不知道为什么oracle会抛出 "无效数据类型"。如果你把这个查询放到匿名块中，你会收到以下信息 PLS-00642: Local Collection Types Not Allowed in SQL Statement

如果你不想或不能创建sql级别的集合。解决方案是使用预定义类型。预定义集合的良好来源是 Oracle Data Cartridge. 替换所有 t_number 与 ODCINumberList.

预定义集合

Answer 2

在Oracle 10和11中，不可能在SQL作用域中使用已在PLSQL作用域中定义的集合。在Oracle 12中，你正在尝试的应该是工作。

如果你想这样做，那么在SQL作用域中声明你的类型（而不是在包中）。

CREATE OR REPLACE TYPE t_col IS OBJECT(
  i NUMBER,
  n VARCHAR2(30)
);
/

CREATE OR REPLACE TYPE t_nested_table IS TABLE OF t_col;
/

CREATE OR REPLACE TYPE t_number IS TABLE OF NUMBER;
/

CREATE OR REPLACE PACKAGE my_pkg IS
  FUNCTION iterate_table RETURN t_number PIPELINED;
  FUNCTION return_table(in_t_num t_number) RETURN t_nested_table PIPELINED;
  g_number t_number ;
  g_nested_number t_nested_table ;
END my_pkg;
/