PL / SQL触发器在更新或插入后更新同一个表

问题描述 投票:-1回答:1

我需要帮助触发器或类似的东西。问题是,我有几行具有相同的id,并且有一个名为status的列。这些行中只有一行可以同时“活动”。在将一行更新为“活动”后,如何将所有其他人更改为“非活动”。

plsql triggers procedure
1个回答
2
投票

正如评论中所建议的那样,您应该在存储过程中执行此操作,该过程可能如下所示:

create or replace procedure prc_ActivateThingy(p_Id number) as
begin
  update YourThingy t
  set t.Active = 'Y'
  where
    t.Id = p_Id;

  dbms_output.put_line(sql%rowcount);

  if sql%rowcount = 0 then
    raise_application_error(-20000, 'No thingy found with id ' || p_Id || '.');
  end if;

  update YourThingy t
  set t.Active = 'N'
  where t.Id <> p_Id;

  dbms_output.put_line(sql%rowcount);
end;

在触发器中执行此操作也会起作用,但如果存在太多“触发魔法”,最终您的应用程序将难以维护。预测什么时候会发生火灾变得更加困难,而且你可能陷入混乱,使得很难实现新的业务逻辑或技术重构。

因此,为了完整性,这是如何在复合触发器中执行此操作,尽管再次建议选择上面的选项。

create or replace trigger tiuc_YourThingy
for insert or update on YourThingy
compound trigger

  v_Id number;

  before each row is
  begin
    v_Id := null;
    if :new.Active = 'Y' then
      v_Id := :new.Id;
    end if;
  end before each row;

  after statement is
  begin
    if v_Id is not null then
      update YourThingy t
      set
        t.ACTIVE = 'N'
      where
        t.ID <> v_Id;
    end if;
  end after statement;

end;