为什么TCNT1不计算Atmega328？

Question

我有以下代码用于带有Atmega328的Arduino和一个通用的16x2 LCD。 LCD工作正常，但始终显示定时器1计数器TCNT1的起始值“333”。为什么？我一遍又一遍地阅读了328的数据表，但我不明白。

    #include <LiquidCrystal.h>

    const int rs = 12, en = 11, d4 = 5, d5 = 4, d6 = 3, d7 = 2;
    LiquidCrystal lcd(rs, en, d4, d5, d6, d7);

    const int lcdContrastPin = 6, lcdBackligthPin = 10;

    void setup() 
    {
      // tutn on LCD backlight and contrast
      pinMode(lcdContrastPin, OUTPUT);
      pinMode(lcdBackligthPin, OUTPUT);

      // fine-tuning contrast could be done by PWM on lcdContrastPin
      digitalWrite(lcdContrastPin, LOW);
      digitalWrite(lcdBackligthPin, HIGH);

      lcd.begin(16, 2);

      // configure Timer1
      TCCR1A = 0; // no waveform generation
      TCCR1B = 0x00000010; // frequency divider 8 (i.e. counting with 2 MHz)
      TCCR1C = 0;
      TIFR1 = 0x00100000; // clear Input Capture Flag
      TCNT1 = 333;
    }

    void loop() 
    {
      int currentTimerValue = TCNT1;

      lcd.setCursor(0, 0);
      lcd.print("TCNT1=");
      lcd.print(currentTimerValue);
      lcd.println("      ");

      delay(50); 
    } 

Answer 1

愚蠢的我！在意识流逝中，我将0x00000010作为二进制数而不是十六进制数。因此，我将所有时钟选择位设置为0，这意味着定时器停止。

在用0b00000010（真正的二进制数）替换0x00000010之后，一切都按预期工作：

      TCCR1B = 0b00000010; // frequency divider 8 (i.e. counting with 2 MHz)
      TCCR1C = 0;
      TIFR1 = 0b00100000; // clear Input Capture Flag