UDF Vlookup总和错误。始终返回“#VALUE！”

Question

我想创建一个函数，函数返回Vlookup的所有返回值的Sum。查找值的参数由“＆”分隔。另外，“DD00”的“DD”，“DD0”必须在参数之前添加以匹配查找范围中的查找值。例如，Cell（1,2）=“DD003＆03A”，该函数应该将DD003和DD003A的返回值相加。以下是我的代码：

Option Explicit

Public Function DPPR_Vlookup(Lookup_Value As String, Lookup_Range As Range, Column_Index As Long, Optional Match_Case As Integer) As Variant

Dim D_Code() As String

Dim Pos_1 As Long

Dim i As Integer

Dim Sum_Value As Long

Dim x1 As Long
Dim x2 As Long
Dim x3 As Long


Pos_1 = InStr(1, Lookup_Value, "&", vbTextCompare)

    With Application.WorksheetFunction

        If Pos_1 = 0 Then

        DPPR_Vlookup = .VLookup(Lookup_Value, Lookup_Range, Column_Index, Match_Case)

        Else

        D_Code() = Split(Lookup_Value, "&")

            Sum_Value = 0

            For i = 1 To UBound(D_Code())

                If IsError(.VLookup("DD" & D_Code(i), Lookup_Range, Column_Index, Match_Case)) = True Then

                x1 = 0

                Else

                x1 = .VLookup("DD" & D_Code(i), Lookup_Range, Column_Index, Match_Case)

                End If


                If IsError(.VLookup("DD0" & D_Code(i), Lookup_Range, Column_Index, Match_Case)) = True Then

                x2 = 0

                Else

                x2 = .VLookup("DD0" & D_Code(i), Lookup_Range, Column_Index, Match_Case)

                End If


                If IsError(.VLookup("DD00" & D_Code(i), Lookup_Range, Column_Index, Match_Case)) = True Then

                x3 = 0

                Else

                x3 = .VLookup("DD00" & D_Code(i), Lookup_Range, Column_Index, Match_Case)

                End If


                Sum_Value = Sum_Value + x1 + x2 + x3

                x1 = 0
                x2 = 0
                x3 = 0

            Next i


DPPR_Vlookup = Sum_Value


        End If

    End With

End Function

带“＆”的所有参数的结果始终为“#VALUE！”。我已经考虑了错误，并且该值应该为0.此外，DD003和DD003A的值都存在于lookup_range中，但该函数仅返回“#VALUE！”。请帮忙。

Answer 1

请注意，对于DD003&03A的第一个值，您不需要添加前缀。 Split方法返回的数组索引也以0开头，因此你需要从i = 0开始，或者用i = LBound(D_Code())动态更好。

正如评论中提到的，WorksheetFunction.Vlookup返回一个无法用IsError()捕获的运行时错误，所以我改为Application.Vlookup。

我还为可能的前缀添加了一个数组，因此我们可以轻松地使用循环而不是反复重复相同的代码。

最后使用测试程序轻松调试您的功能，这样您就可以使用F8逐步完成它。

Option Explicit

Public Sub Test_DPPR_Vlookup()

    Debug.Print DPPR_Vlookup([E2], [A:B], 2, 0)

End Sub

Public Function DPPR_Vlookup(Lookup_Value As String, Lookup_Range As Variant, Column_Index As Variant, Optional Match_Case As Boolean) As Variant
    Dim Pos_1 As Long
    Pos_1 = InStr(1, Lookup_Value, "&", vbTextCompare)

    Dim Prefix As Variant
    Dim Prefixes() As Variant
    Prefixes = Array("", "DD", "DD0", "DD00") 'note that the first is needed to also lookup without prefixes (first item)

    With Application
        If Pos_1 = 0 Then
            DPPR_Vlookup = .VLookup(Lookup_Value, Lookup_Range, Column_Index, Match_Case)
        Else
            Dim D_Code() As String
            D_Code() = Split(Lookup_Value, "&")

            Dim Sum_Value As Long
            Sum_Value = 0

            Dim i As Long, LookupResult As Variant
            For i = 0 To UBound(D_Code()) 'note array item counting starts with 0
                For Each Prefix In Prefixes
                    LookupResult = .VLookup(Prefix & D_Code(i), Lookup_Range, Column_Index, Match_Case)
                    If Not IsError(LookupResult) Then
                        Sum_Value = Sum_Value + LookupResult
                    End If
                Next Prefix
            Next i

            DPPR_Vlookup = Sum_Value
        End If
    End With
End Function

用于Result的公式是=DPPR_Vlookup(E2,A:B,2,0)