如何在 Groovy 中将列表拆分为大小相等的列表？

问题描述 投票：0回答：10

如果我有这个：

def array = [1,2,3,4,5,6]

是否有一些内置功能可以让我执行此操作（或类似的操作）：

array.split(2)

并得到：

[[1,2],[3,4],[5,6]]

？

list groovy built-in
10个回答
87
投票

编辑从groovy 1.8.6开始，您可以在列表上使用collate方法

def origList = [1, 2, 3, 4, 5, 6, 7, 8, 9]
assert [[1, 2, 3, 4], [5, 6, 7, 8], [9]] == origList.collate(4)

另一种使用注入和元类的方法

List.metaClass.partition = { size ->
  def rslt = delegate.inject( [ [] ] ) { ret, elem ->
    ( ret.last() << elem ).size() >= size ? ret << [] : ret
  }
  if( rslt.last()?.size() == 0 ) rslt.pop()
  rslt
}

def origList = [1, 2, 3, 4, 5, 6]

assert [ [1], [2], [3], [4], [5], [6] ] == origList.partition(1)
assert [ [1, 2], [3, 4], [5, 6] ]       == origList.partition(2)
assert [ [1, 2, 3], [4, 5, 6] ]         == origList.partition(3)
assert [ [1, 2, 3, 4], [5, 6] ]         == origList.partition(4)
assert [ [1, 2, 3, 4, 5], [6] ]         == origList.partition(5)
assert [ [1, 2, 3, 4, 5, 6] ]           == origList.partition(6)
assert [ ]                              == [ ].partition(2)

编辑：修复了空列表的问题

22
投票

我同意 Chris 的观点，groovy 中没有内置任何东西来处理这个问题（至少对于 2 个以上的分区），但我将你的问题解释为提出了与他不同的问题。这是一个实现我认为您所要求的功能：

def partition(array, size) {
    def partitions = []
    int partitionCount = array.size() / size

    partitionCount.times { partitionNumber ->
        def start = partitionNumber * size 
        def end = start + size - 1
        partitions << array[start..end]    
    }

    if (array.size() % size) partitions << array[partitionCount * size..-1]
    return partitions    
}


def origList = [1, 2, 3, 4, 5, 6]
assert [[1], [2], [3], [4], [5], [6]] == partition(origList, 1)
assert [[1, 2], [3, 4], [5, 6]] == partition(origList, 2)
assert [[1, 2, 3], [4, 5, 6]] == partition(origList, 3)
assert [[1, 2, 3, 4], [5, 6]] == partition(origList, 4)
assert [[1, 2, 3, 4, 5], [6]] == partition(origList, 5)
assert [[1, 2, 3, 4, 5, 6]] == partition(origList, 6)
17
投票

查看 groovy 1.8.6。 List 上有一个新的整理方法。

def list = [1, 2, 3, 4]
assert list.collate(4) == [[1, 2, 3, 4]] // gets you everything   
assert list.collate(2) == [[1, 2], [3, 4]] //splits evenly
assert list.collate(3) == [[1, 2, 3], [4]] // won't split evenly, remainder in last list.

查看 Groovy List 文档 了解更多信息，因为还有一些其他参数可以为您提供一些其他选项，包括删除其余部分。

9
投票

我正在寻找同样的问题，我发现列表的

collate()
方法非常有用。

array.collate(2)

这里是文档的链接。

4
投票

没有内置的东西可以做到这一点，但写起来并不难：

def array = [1,2,3,4,5,6]
int mid = (int) (array.size() / 2)
def left = array[0..mid-1]
def right = array[mid..array.size()-1]

println left
println right
3
投票

这是一个替代版本，它使用 Groovy 的动态功能向 List 类添加 split 方法，这可以达到您的预期：

List.metaClass.split << { size ->
  def result = []
  def max = delegate.size() - 1
  def regions = (0..max).step(size)

  regions.each { start ->
     end =  Math.min(start + size - 1, max)
     result << delegate[start..end]
  }

  return result
}

def original = [1, 2, 3, 4, 5, 6]
assert [[1, 2], [3, 4], [5, 6]] == original.split(2)
2
投票

我知道这太老了 - 但对于那些希望将列表分割成相等的分区（带有余数）的人，并且您错过了 Tim 对原始帖子的评论，最新的常规方法是 List 对象的 collate() 方法，该方法具有自 Groovy 1.8.6 起可用。

def array = [1, 2, 3, 4, 5, 6, 7]

assert [[1], [2], [3], [4], [5], [6], [7]] == array.collate(1, 1, true)
assert [[1, 2], [3, 4], [5, 6], [7]] == array.collate(2, 2, true)
assert [[1, 2, 3], [4, 5, 6], [7]] == array.collate(3, 3, true)
assert [[1, 2, 3, 4], [5, 6, 7]] == array.collate(4, 4, true)
assert [[1, 2, 3, 4, 5], [6, 7]] == array.collate(5, 5, true)
assert [[1, 2, 3, 4, 5, 6], [7]] == array.collate(6, 6, true)
assert [[1, 2, 3, 4, 5, 6, 7]] == array.collate(7, 7, true)
1
投票
List.metaClass.split << { step ->
    def result = [], max = delegate.size(), min = 0 

    while(min+step < max){       
        result.add delegate.subList(min,min+=step)
    }
    result.add delegate.subList(min, max)

    result
}
0
投票

这个问题很老了，但无论如何我想分享我想出的将列表拆分为相等大小的列表的方法。

list.collate
很棒，但对我来说不起作用，因为我需要均匀地分割列表。

我在哪里做什么：

class PartitionCategory {

    static evenlyPartitionWithCount(Collection self, int count) {
        def indexes = 0..<self.size()
        def sizes = indexes.countBy({ i -> i % count }).values()
        def ranges = sizes.inject([]) { a, v -> a << (a ? (a.last().last() + 1)..(a.last().last() + v) : 0..<v) }
        ranges.collect { r -> self[r] }
    }

    static evenlyPartitionWithSize(Collection self, int size) {
        self.evenlyPartitionWithCount((int) Math.ceil(self.size() / size))
    }

}

def array = [1, 2, 3, 4, 5, 6, 7]

use (PartitionCategory) {
assert [[1], [2], [3], [4], [5], [6], [7]] == array.evenlyPartitionWithSize(1)
assert [[1, 2], [3, 4], [5, 6], [7]] == array.evenlyPartitionWithSize(2)
assert [[1, 2, 3], [4, 5], [6, 7]] == array.evenlyPartitionWithSize(3)
assert [[1, 2, 3, 4], [5, 6, 7]] == array.evenlyPartitionWithSize(4)
assert [[1, 2, 3, 4], [5, 6, 7]] == array.evenlyPartitionWithSize(5)
assert [[1, 2, 3, 4], [5, 6, 7]] == array.evenlyPartitionWithSize(6)
assert [[1, 2, 3, 4, 5, 6, 7]] == array.evenlyPartitionWithSize(7)
}
0
投票

我的groovy很老了，而且我没有柯林德。我实现了一个小型递归函数，其工作原理类似于 Java 中的 Lists.partition 

private static partitionList(list, result, partitionSize) {
     if (list == []) {
         return result
     }

     if (list.size() <= partitionSize) {
         result.add(list[0..list.size() - 1])
         return result
     }

     result.add(list[0..partitionSize - 1])
     return partitionList(list[partitionSize..list.size() - 1], result, partitionSize)
}

private static partitionList(list, partitionSize) {
     return partitionList(list, [], partitionSize)
}

其工作原理如下

def arr1 = [1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11]
partitions = partitionList(arr1, 7)
assert partitions.size() == 2
assert partitions[0] == [1, 2, 3, 4, 5, 6, 7]
assert partitions[1] == [8, 9, 10, 11]
最新问题
© www.soinside.com 2019 - 2024. All rights reserved.