使用带有默认参数和重载过程的字符串数组

Question

我有这个代码，有一个使用重载和默认参数的过程：

program Project2;
{$APPTYPE CONSOLE}
uses SysUtils;

procedure Foo; overload; // not actually needed to reproduce
begin
end;

procedure Foo(const a: array of string; b: Boolean=False); overload;
begin
  Writeln(Length(a));
end;

begin
  Foo(['1', '2', '3']); // => 1 ???
  Foo(['1', '2', '3'], False); // => 3 OK
  Readln;
end.

输出是：

1
3

请注意，第一次调用Foo时不提供默认值。为什么会这样？这个问题只与很老的编译器有关吗？

只有在使用overload密钥时才会发生这种情况。

procedure Foo2(const a: array of string; b: Boolean=False);
begin
  Writeln(Length(a));
end;

Foo2(['1', '2', '3']);

工作良好。

Answer 1

摘要

正如您所发现的那样，David帮助澄清：这是Delphi 5中的一个错误（可能还有那个时代的其他几个版本）。在特定条件下，编译器无法正确调用该过程。

它本质上是两个功能的冲突：

• 开放数组允许调用者将未指定长度的固定数组传递给过程。编译器在编译时确定长度并传递一个额外的隐藏参数（High索引），以便该方法可以正确地确定数组中的元素数。
• 默认参数只是语法糖，允许调用者省略默认值。实现不受影响，但编译器会自动传递省略的参数，就像调用者已通过默认值一样。
• 当过程标记为过载时，会发生错误。编译器似乎“忘记”传递隐藏的High索引，并在其位置传递默认值。

---

解决方法

我确定你已经在使用明显的解决方法了，但我将其包含在内是为了完整性。当我以前在Delphi 5中工作时，我们将array of String和default的所有组合替换为以下内容; （无论我们是否已经使用overload）。

procedure Foo(const a: array of string; b: Boolean); overload; {Remove the default}
begin
  ...
end;
procedure Foo(const a: array of string); overload;
begin
  Foo(a, False); {And pass the default value via overload}
end;

---

细节

您可以通过在CPU窗口（Ctrl + Alt + C）中调试并检查汇编代码来准确地观察编译器如何无法正确调用Foo。

你应该能够推断出Foo程序被编译为期望：

• eax中打开数组的地址
• ecx中的第二个参数（默认值）
• High中阵列的edx指数

注意我使用Integer默认值来获得更独特的默认值。

Case 1

procedure Foo(const a: array of string; b: Integer = 7);
...
Foo(['a', 'b', 'c']);
{The last few lines of assembler for the above call}
lea eax,[ebp-$18] {Load effective address of array}
mov ecx,$00000007 {Implicitly set default value 7}
mov edx,$00000002 {The hidden High value of the open array}
call Foo

Case 2

procedure Foo(const a: array of string; b: Integer = 7); overload;
...
Foo(['a', 'b', 'c']);

lea eax,[ebp-$18]
{The second parameter is now uninitialised!}
mov edx,$00000007 {Instead the default is assigned to register for High(a)}
call Foo

Case 3

procedure Foo(const a: array of string; b: Integer = 7); overload;
...
Foo(['a', 'b', 'c'], 5);

lea eax,[ebp-$18]
mov ecx,$00000005 {The explicit argument for 2nd parameter}
mov edx,$00000002 {The hidden parameter is again correctly assigned}
call Foo

---

补充意见

1）正如上面的案例2中所指出的，当bug出现时，ecx没有被初始化。以下应证明效果：

procedure Foo(const a: array of string; b: Integer = 2); overload;
var
  I: Integer;
begin
  for I := Low(a) to High(a) do Write(a[I]);
  Writeln(b);
end;
...
Foo(['a', 'b', 'c'], 23); {Will write abc23}
Foo(['a', 'b', 'c']); {Will write abc, but the number probably won't be 2}

2）动态数组不会显示错误。动态数组的长度是其内部结构的一部分，因此不能忘记。

Answer 2

这显然是Delphi-5中的一个错误。只有满足以下条件才会发生：

• 该程序标有overload
• array of string是第一个参数
• 没有默认参数传递给过程