如何在Windows上静默安装Android SDK给所有用户？

Question

android-studio-bundle-162.4069837-windows.exe /S

正在将 Android studio 安装到 c:\program files ndroid ndroid studio。和 SDK 到 %localappdata% ndroid\sdk。

在一些论坛中提到使用 /AllUsers 为所有用户安装 SDK。

我试过了 android-studio-bundle-162.4069837-windows.exe /S /AllUsers android-studio-bundle-162.4069837-windows.exe /S /ALLUSERS

但是没有用，它只是安装到本地应用程序数据。

即使使用 /S，即使在配置之后，我每次启动时也会看到 SDK 丢失的屏幕。

我只尝试了没有 SDK 的工作室安装

https://developer.android.com/studio/index.html

“C:\Users\uday\下载 ndroid-studio-ide-162.4069837-windows.exe”/S

通过快捷方式启动，我将 SDK 安装到 programdata 并授予所有用户对该文件夹的完全权限。

如果我看到设置位于 c:\users\username.Android 和 .AndroidStudio2.3 文件夹中。

但是相同的文件夹，如果我复制到其他用户，它只是将 SDK 文件夹作为程序数据，但提示未检测到 SDK，需要重新下载，即使我跳过它并转到设置，它也显示为空指向到同一个文件夹。

有什么建议吗？

Answer 1

似乎没有任何内置的方法可以做到这一点，但这就是我所做的。 YMMV。另外，我是从教室的角度来做这件事的，学生的用户配置文件在重新启动时会被清除。

安装 A.S. 3.0.x.

以受限用户身份登录（无管理员权限）。 运行 A.S.，进入设置，然后将 SDK 位置更改为（示例）c:\AndroidStudioSDK。确保您以受限用户身份创建了此文件夹。

完全更新，安装所需的 SDK 和组件，并构建项目，解决所有缺少的组件和问题。

文件 > 使缓存失效，然后单击使缓存失效。然后文件>导出设置，并将其保存到桌面。然后从用户的主文件夹中删除或移出以下文件夹：.android、.AndroidStudio3.0 和 .Gradle。 运行 A.S.但取消向导，选择不要重新运行设置向导，单击配置>导入设置，然后从桌面导入settings.jar文件。重新启动后，您可以单击 Configure > SDK Manager 验证它仍然指向您的自定义位置。

关闭 A.S.，然后将（现在很小）.android 和 .AndroidStudio3.0 文件夹复制到 c:\users\default。

瞧。任何登录的新用户都应该有一个指向中央 SDK 文件夹的就绪环境。您可以将 SDK 文件夹和默认用户文件夹复制到每台实验室 PC。

我已经包含了部署时使用的（经过清理的）Windows 批处理文件。

希望这有帮助。

@echo off
cd /d %0\.. & color 0e & setlocal

::this code assumes that 7zip is installed at "%ProgramFiles%\7-zip\7z.exe"

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
set "installer=android-studio-ide-171.4443003-windows.exe"
set "SDKfolder=AndroidStudioSDK"
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO %installer%
ECHO.
ECHO Installing Android Studio...
%installer% /S

netsh advfirewall firewall add rule Name="OpenJDK Platform binary" Program="C:\Program Files\Android\Android Studio\jre\bin\java.exe" Description="Part of Android Studio" Action=Allow Direction=In Protocol=6
netsh advfirewall firewall add rule Name="OpenJDK Platform binary" Program="C:\Program Files\Android\Android Studio\jre\bin\java.exe" Description="Part of Android Studio" Action=Allow Direction=In Protocol=17

::Install Intel HAXM
cmd /c %CD%\HAXM\silent_install.bat

::Install Default user files
"%ProgramFiles%\7-zip\7z.exe" x userfolders.7z -o%CD% -y
set "defaultUserDir=%SystemDrive%\Users\Default"
if exist %defaultUserDir%\.android (rmdir /s /q %defaultUserDir%\.android)
if exist %defaultUserDir%\.AndroidStudio3.0 (rmdir /s /q %defaultUserDir%\.AndroidStudio3.0)
move %CD%\.android %SystemDrive%\Users\Default
move %CD%\.AndroidStudio3.0 %SystemDrive%\Users\Default

::Install SDK files
"%ProgramFiles%\7-zip\7z.exe" x %SDKfolder%.7z -o%CD% -y
if exist %SystemDrive%\%SDKfolder% (rmdir /s /q %SystemDrive%\%SDKfolder%)
move %CD%\%SDKfolder% %SystemDrive%\

timeout 9
:END
color & endlocal
EXIT 0