UTL_FILE.FOPEN() 程序不接受目录路径？

Question

我正在尝试写入存储在 c:\ 驱动器中名为 vin1.txt 的文件 并收到此错误。请提出建议！

> ERROR at line 1: ORA-29280: invalid
> directory path ORA-06512: at
> "SYS.UTL_FILE", line 18 ORA-06512: at
> "SYS.UTL_FILE", line 424 ORA-06512: at
> "SCOTT.SAL_STATUS", line 12 ORA-06512:
> at line 1

这里是代码

  create or replace procedure sal_status
   (
    p_file_dir IN varchar2,
    p_filename IN varchar2)
     IS  
    v_filehandle utl_file.file_type;
    cursor emp Is
        select * from employees
        order by department_id;
    v_dep_no departments.department_id%TYPE;
     begin
         v_filehandle :=utl_file.fopen(p_file_dir,p_filename,'w');--Opening a file
         utl_file.putf(v_filehandle,'SALARY REPORT :GENERATED ON %s\n',SYSDATE);
         utl_file.new_line(v_filehandle);
         for v_emp_rec IN emp LOOP
            v_dep_no :=v_emp_rec.department_id;
            utl_file.putf(v_filehandle,'employee %s earns:s\n',v_emp_rec.last_name,v_emp_rec.salary);                    
         end loop;
        utl_file.put_line(v_filehandle,'***END OF REPORT***');
        UTL_FILE.fclose(v_filehandle);
     end sal_status;

execute sal_status('C:\','vin1.txt');--Executing

Answer 1

自 Oracle 9i 以来，有两种方法或声明与 UTL_FILE 一起使用的目录。

老办法是设置INIT.ORA参数UTL_FILE_DIR。我们必须重新启动数据库才能使更改生效。该值可以像任何其他 PATH 变量一样；它接受通配符。使用这种方法意味着传递目录路径...

UTL_FILE.FOPEN('c:\temp', 'vineet.txt', 'W');

9i 中引入的替代方法是声明一个目录对象。

create or replace directory temp_dir as 'C:\temp'
/

grant read, write on directory temp_dir to vineet
/

目录对象需要准确的文件路径，不接受通配符。在这种方法中，我们传递目录对象名称...

UTL_FILE.FOPEN('TEMP_DIR', 'vineet.txt', 'W');

UTL_FILE_DIR 已被弃用，因为它本质上是不安全的——所有用户都可以访问路径中指定的所有操作系统目录，而目录对象的读写权限可以单独授予单个用户。此外，使用 Directory 对象，我们可以添加、删除或更改目录而无需弹回数据库。

在任何一种情况下，

oracle

OS 用户必须对 OS 目录具有读和/或写权限。如果不明显，这意味着目录必须从数据库服务器可见。因此，我们不能使用任何一种方法将本地 PC 上的目录公开给远程数据库服务器上运行的进程。文件必须上传到数据库服务器或共享网络驱动器。

---

如果

oracle

OS 用户在 OS 目录上没有适当的权限，或者如果数据库中指定的路径与实际路径不匹配，程序将抛出此异常：

ORA-29283: invalid file operation
ORA-06512: at "SYS.UTL_FILE", line 536
ORA-29283: invalid file operation
ORA-06512: at line 7

此错误的 OERR 文本非常清楚：

29283 -  "invalid file operation"
*Cause:    An attempt was made to read from a file or directory that does
           not exist, or file or directory access was denied by the
           operating system.
*Action:   Verify file and directory access privileges on the file system,
           and if reading, verify that the file exists.

---

从 Oracle 18c 开始，不支持 UTL_FILE_DIR，除了向后兼容。

Answer 2

也不要忘记文件的路径在实际的 oracle 服务器机器上，而不是任何可能调用存储过程的本地开发机器上。这可能很明显，但应该记住。

Answer 3

您需要向 Oracle 注册目录。 fopen 采用目录对象的名称，而不是路径。例如：

（您可能需要以 SYS 身份登录才能执行这些操作）

CREATE DIRECTORY MY_DIR AS 'C:\';

GRANT READ ON DIRECTORY MY_DIR TO SCOTT;

然后在fopen的调用中可以参考：

execute sal_status('MY_DIR','vin1.txt');

Answer 4

目录名好像是区分大小写的。我遇到了同样的问题，但是当我以大写形式提供目录名称时，它起作用了。

Answer 5

您需要让您的DBA 修改init.ora 文件，将您要访问的目录添加到'utl_file_dir' 参数中。然后您的数据库实例将需要停止并重新启动，因为 init.ora 仅在数据库启动时读取。

您可以通过运行以下查询来查看（但不能更改）此参数：

SELECT *
  FROM V$PARAMETER
  WHERE NAME = 'utl_file_dir'

分享和享受。

Answer 6

对于 utl_file.open(location,filename,mode) ，我们需要为位置提供目录名称而不是路径。例如：DATA_FILE_DIR，这是目录名称并检查该特定目录名称的目录路径。