删除多行注释

Question

如果它们以/ *开头并以*结尾，我如何删除所有注释？我尝试了以下操作。它适用于一行评论。

sed '/\/\*/d' 

但它不会删除多行注释。例如第二行和第三行未删除。

/*!50500 PARTITION BY RANGE (TO_SECONDS(date_time ))
 PARTITION 20120102parti VALUES LESS THAN (63492681600),
(PARTITION 20120101parti VALUES LESS THAN (63492595200) */ ;

在上面的例子中，我需要保留最后一个;在结束评论标志后。

Answer 1

如果这是在C文件中，那么你必须使用C预处理器与其他工具结合使用来暂时禁用特定的预处理器功能，如扩展#defines或#includes，所有其他方法在边缘情况下都会失败。这适用于所有情况：

[ $# -eq 2 ] && arg="$1" || arg=""
eval file="\$$#"
sed 's/a/aA/g; s/__/aB/g; s/#/aC/g' "$file" |
          gcc -P -E $arg - |
          sed 's/aC/#/g; s/aB/__/g; s/aA/a/g'

将它放在shell脚本中，并使用您要解析的文件的名称调用它，可选择使用“-ansi”之类的标记作为前缀，以指定要应用的C标准。

有关详细信息，请参阅https://stackoverflow.com/a/35708616/1745001。

Answer 2

这是使用GNU sed的一种方式。像sed -rf script.sed file.txt一样跑

script.sed的内容：

:a
s%(.*)/\*.*\*/%\1%
ta
/\/\*/ !b
N
ba

或者，这是一个班轮：

sed -r ':a; s%(.*)/\*.*\*/%\1%; ta; /\/\*/ !b; N; ba' file.txt

Answer 3

这应该做

 sed 's|/\*|\n&|g;s|*/|&\n|g' a.txt | sed '/\/\*/,/*\//d'

测试：

A.TXT

/* Line test
multi
comment */
Hello there
this would stay 
/* this would be deleteed */

命令：

$ sed 's|/\*|\n&|g;s|*/|&\n|g' a.txt | sed '/\/\*/,/*\//d'
Hello there
this would stay 

Answer 4

为了补充Ed的答案（专注于C文件），我建议由Brian Hiles为非C文件（例如PL / SQL文件）提供优秀的sed脚本remccoms3.sed。它处理C和C ++（//）注释并正确地跳过字符串中的注释。该脚本可在此处获取：http://sed.sourceforge.net/grabbag/scripts/remccoms3.sed

Answer 5

这可能适合你（GNU sed）：

sed -r ':a;$!{N;ba};s|/\*[^*]*\*+([^/*][^*]*\*+)*/||' file

无论如何，这是一个开始！

Answer 6

试试这个

sed "/^\//,/\/;/d" filename

Answer 7

仅限sed的解决方案：

sed -r 's/\/\*(.*?)\*\///g' \
    | sed -r 's/(.+)(\/\*)/\1\n\2/g'\
    | sed -r 's/(\*\/)(.+)/\1\n\2/g' \
    | sed '/\/\*/,/\*\// s/.*//'

缺点：多行注释会留空行（因为sed是基于行的，除非你付出超人的努力）。

说明

• s/\/\*(.*?)\*\///g将负责单行评论。
• s/(.+)(\/\*)/\1\n\2/g和s/(\*\/)(.+)/\1\n\2/g将在多行评论的开头和结尾分割线条。
• /\/\*/,/\*\// s/.*//将运行命令s/.*//有效地删除模式\/\*和\*\/之间的所有线 - 这是/*和*/逃脱。