从Windows注册表保存和检索布尔值

Question

我正在尝试使用Delphi Rio（Firemonkey）从Windows注册表中保存/检索布尔值。无论我保存哪种状态，无论是真还是假，代码始终返回一个真值。这是一个示例项目，说明了我的方法：

uses
  System.IniFiles, System.Win.Registry;

const
  AppRegKey = 'Software\Mycroft\TestApp';

procedure TForm2.btnReadClick(Sender: TObject);
var
  Reg: TCustomIniFile;
  checked: boolean;
begin
  Reg := TRegistryIniFile.Create('');
  checked := False;
  if Reg.SectionExists(AppRegKey + '\State\BoxChecked') then begin
    checked := Reg.ReadBool(AppRegKey,'Show', True);
  end;
  if checked then
    ShowMessage('Checked')
  else
    ShowMessage('Unchecked');
end;

procedure TForm2.btnSaveClick(Sender: TObject);
var
  Reg: TCustomIniFile;

begin
  Reg := TRegistryIniFile.Create('');
  Reg.WriteBool(AppRegKey + '\State\BoxChecked', 'Show', chkBrandNew.IsChecked);
end;

似乎注册表中正在更新该值，所以我不确定为什么它总是返回True值。有人可以指出正确的方向吗？

Answer 1

您没有将与Reg.ReadBool()相同的键名传递给Reg.WriteBool()。

您还将泄漏TRegistryIniFile对象。

尝试以下方法：

uses
  System.IniFiles, System.Win.Registry;

const
  AppRegKey = 'Software\Mycroft\TestApp';
  AppRegKey_BoxChecked = AppRegKey + '\State\BoxChecked';

procedure TForm2.btnReadClick(Sender: TObject);
var
  Reg: TCustomIniFile;
  checked: boolean;
begin
  Reg := TRegistryIniFile.Create('');
  try
    checked := False;
    if Reg.SectionExists(AppRegKey_BoxChecked) then
    begin
      checked := Reg.ReadBool(AppRegKey_BoxChecked, 'Show', True);
    end;
    if checked then
      ShowMessage('Checked')
    else
      ShowMessage('Unchecked');
  finally
    Reg.Free;
  end;
end;

procedure TForm2.btnSaveClick(Sender: TObject);
var
  Reg: TCustomIniFile;
begin
  Reg := TRegistryIniFile.Create('');
  try
    Reg.WriteBool(AppRegKey_BoxChecked, 'Show', chkBrandNew.IsChecked);
  finally
    Reg.Free;
  end;
end;

也就是说，TRegistryIniFile旨在与旧代码向后兼容，该旧代码用于使用TIniFile保存配置，然后迁移到注册表。新代码完全不应使用TRegistryIniFile。

uses
  System.Win.Registry;

const
  AppRegKey = 'Software\Mycroft\TestApp';
  AppRegKey_BoxChecked = AppRegKey + '\State\BoxChecked';

procedure TForm2.btnReadClick(Sender: TObject);
var
  Reg: TRegistry;
  checked: boolean;
begin
  Reg := TRegistry.Create;
  //Reg := TRegistry.Create(KEY_QUERY_VALUE);
  try
    checked := False;
    if Reg.OpenKeyReadOnly(AppRegKey_BoxChecked) then
    // if Reg.OpenKey(AppRegKey_BoxChecked, False) then
    begin
      if Reg.ValueExists('Show') then
        checked := Reg.ReadBool('Show')
      else
        checked := True;
      Reg.CloseKey;
    end;
    if checked then
      ShowMessage('Checked')
    else
      ShowMessage('Unchecked');
  finally
    Reg.Free;
  end;
end;

procedure TForm2.btnSaveClick(Sender: TObject);
var
  Reg: TRegistry;
begin
  Reg := TRegistry.Create(KEY_SET_VALUE);
  try
    if Reg.OpenKey(AppRegKey_BoxChecked, True) then
    begin
      Reg.WriteBool('Show', chkBrandNew.IsChecked);
      Reg.CloseKey;
    end;
  finally
    Reg.Free;
  end;
end;