镜头中有类型类自动生成的文档在哪里？

Question

我正在查看这个blog post（也是here）的倒数第二个例子，在验证它运行之后，它似乎证实镜头可以生成有类型类，我采取的是博客作者的暗示。但是，我想念这里描述的地方，无论是在lens contents还是lens tutorial。官方文档之外关于如何做到的任何解释也将受到欢迎。但是在使用最基本的功能（makeLenses，或者在这种情况下，makeLensesWith）时，似乎这可能只是标准。

这是再现的代码：

#!/usr/bin/env stack
-- stack --resolver lts-8.12 script
{-# LANGUAGE FlexibleContexts #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE TemplateHaskell #-}
{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE FunctionalDependencies #-}
import Control.Concurrent.Async.Lifted.Safe
import Control.Monad.Reader
import Control.Concurrent.STM
import Say
import Control.Lens
import Prelude hiding (log)

data Env = Env
  { envLog :: !(String -> IO ())
  , envBalance :: !(TVar Int)
  }

makeLensesWith camelCaseFields ''Env

modify :: (MonadReader env m, HasBalance env (TVar Int), MonadIO m)
       => (Int -> Int)
       -> m ()
modify f = do
  env <- ask
  liftIO $ atomically $ modifyTVar' (env^.balance) f

logSomething :: (MonadReader env m, HasLog env (String -> IO ()), MonadIO m)
             => String
             -> m ()
logSomething msg = do
  env <- ask
  liftIO $ (env^.log) msg

main :: IO ()
main = do
  ref <- newTVarIO 4
  let env = Env
        { envLog = sayString
        , envBalance = ref
        }
  runReaderT
    (concurrently
      (modify (+ 1))
      (logSomething "Increasing account balance"))
    env
  balance <- readTVarIO ref
  sayString $ "Final balance: " ++ show balance

Answer 1

Field是lens用于描述每个命名字段的一个类的模式，允许多个记录具有相同的字段名称但（可选）不同类型。所以camelCaseFields，makeFieldOptics，defaultFieldRules都在他们的名字中说，他们将以HasFoo的通常简洁风格生成这些lens课程。

makeClassy还生成名为Has*的类，但以数据类型命名，而不是记录字段，并且不遵循不同的模式。

上面的代码生成以下代码（与-ddump-splices一起显示）：

    makeLensesWith camelCaseFields ''Env
  ======>
    class HasBalance s a | s -> a where
      balance :: Lens' s a
    instance HasBalance Env (TVar Int) where
      {-# INLINE balance #-}
      balance f_a4eTr (Env x1_a4eTs x2_a4eTt)
        = (fmap (\ y1_a4eTu -> (Env x1_a4eTs) y1_a4eTu)) (f_a4eTr x2_a4eTt)
    class HasLog s a | s -> a where
      log :: Lens' s a
    instance HasLog Env (String -> IO ()) where
      {-# INLINE log #-}
      log f_a4eTx (Env x1_a4eTy x2_a4eTz)
        = (fmap (\ y1_a4eTA -> (Env y1_a4eTA) x2_a4eTz)) (f_a4eTx x1_a4eTy)