NSIS：从函数调用MUI_PAGE_LICENSE但得到“XPStyle无效”错误

Question

我有一个带有“许可条款和条件”的自定义对话框。复选框，其中复选框的文本实际上是一个链接，可以显示许可证对话框。

; === LicenseLink (type: Link) ===
${NSD_CreateLink} 132.96u 100.92u 107.29u 14.15u "License terms and conditions."
Pop $hCtl_welcome_LicenseLink
${NSD_OnClick} $hCtl_welcome_LicenseLink ShowLicense

现在在“ShowLicense”功能中我尝试了调用

!insertmacro MUI_PAGE_LICENSE

但得到一个错误：错误：命令XPStyle在Function中无效

显然我正在接近这个错误，我无法解释错误。对于如何解决这个问题的任何想法都会很高兴。

谢谢！

Answer 1

您无法动态调用!insertmacro MUI_PAGE_LICENSE，页面数量是在编译时确定的。

但是，您可以跳过页面来实现此目的：

InstallDir "$Temp\Test"

!include MUI2.nsh
!include nsDialogs.nsh
!include WinMessages.nsh
!include LogicLib.nsh

!define MUI_PAGE_CUSTOMFUNCTION_PRE SkipLicensePage
!insertmacro MUI_PAGE_LICENSE "${__FILE__}"
Page Custom InfoPageCreate InfoPageValidate
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE English


Var ShowLicensePage
Function SkipLicensePage
${IfThen} $ShowLicensePage = 0 ${|} Abort ${|} ; Skip it the first time
FunctionEnd

Function OnShowLicense
SendMessage $hWndParent ${WM_COMMAND} 3 "" ; Click the (hidden) back button
FunctionEnd

Var InstDirCtl
Function InfoPageCreate
StrCpy $ShowLicensePage 1
GetDlgItem $0 $hWndParent 3
ShowWindow $0 0 ; Hide the back button
!insertmacro MUI_HEADER_TEXT "Blah blah" "blah blah blah"
nsDialogs::Create 1018
Pop $0

${NSD_CreateText} 0 13u 100% 12u "$InstDir"
Pop $InstDirCtl

${NSD_CreateLink} 2u 40u -4u 12u "License"
Pop $0
${NSD_OnClick} $0 OnShowLicense

nsDialogs::Show
FunctionEnd

Function InfoPageValidate
${NSD_GetText} $InstDirCtl $InstDir
FunctionEnd