如何在按下按钮时在命令提示符中执行命令并获取 ActionScript 中的输出？

Question

我有一个使用 Flex 的 GUI。我有一个条件，比如我需要在本地计算机中执行一些命令行参数并将结果返回或输出回文本框区域。我如何在提交上执行按钮，在本地计算机中执行命令并返回输出？

Command to execute example: 

    echo logfile.log | grep username

Code:

button1.onRelease = function () 
{
    // in this computer, it will now run a command, please wait.
}

我的答案参考：https://gist.github.com/993905

Answer 1

您将无法使用 ActionScript 2 执行此操作，也将无法在 Flash Web 播放器中使用 ActionScript 3 执行此操作。您可以使用某些工具来使用 ActionScript 2 和 3 创建投影仪来添加这种扩展功能，但您不能简单地从网络上执行此操作，因为这当然会带来极大的安全风险。

但是，您可以使用 Adobe AIR 2.0 或更高版本来执行此操作。您可以使用 NativeProcess 类并检测操作系统，启动终端或 cmd.exe，然后可以针对它运行命令。下面是我开发的一个项目中的一些代码，用于使用 AIR 对操作系统运行命令，就像您尝试做的那样：

private var os:String;
private var consoleExecutable:File;
private var consoleNativeProcess:NativeProcess;

private function usbMounted(e:StorageVolumeChangeEvent):void 
{
    //status.appendText('Device: ' + e.storageVolume.name + ' mounted to drive: ' + e.storageVolume.drive + '\n');
    
    os = Capabilities.os.substr(0, 3).toLowerCase();
    
    switch (os) 
    {
        case "win":
            //Windows OS
            var rootDirs:Array = File.getRootDirectories();
            
            var i:int = 0;
            for (i; i < rootDirs.length; ++i) {
                consoleExecutable = rootDirs[i] as File;
                consoleExecutable  = consoleExecutable.resolvePath("Windows");
                if (consoleExecutable.exists == true) {
                    consoleExecutable = consoleExecutable.resolvePath("System32");
                    consoleExecutable = consoleExecutable.resolvePath("cmd.exe");
                    i = rootDirs.length;                                    
                }                   
            }
            
        break;
        
        case "lin":
            //Linux OS
            
        break;
        
        case "mac":
            //Mac OS
            
        break;
        
        case "iph":
            //Iphone OS
            
        break;
    }   

    var consoleNativeProcessStartupNfo:NativeProcessStartupInfo = new NativeProcessStartupInfo();
    consoleNativeProcessStartupNfo.executable = consoleExecutable;
    var startupArgs:Vector.<String> = new Vector.<String>();
    
    startupArgs.push('/C fsutil fsinfo volumeinfo ' + e.storageVolume.drive + ':');
    
    consoleNativeProcessStartupNfo.arguments = startupArgs;         
    consoleNativeProcess = new NativeProcess();
    consoleNativeProcess.addEventListener(ProgressEvent.STANDARD_OUTPUT_DATA, consoleOutput);           
    consoleNativeProcess.start(consoleNativeProcessStartupNfo);         
    consoleNativeProcess.closeInput();
}       

private function consoleOutput(e:ProgressEvent):void 
{
    var consoleOuput:String = consoleNativeProcess.standardOutput.readUTFBytes(consoleNativeProcess.standardOutput.bytesAvailable);
    
    switch (os) 
    {
        case "win":
            //Windows OS
            
        break;
        
        case "lin":
            //Linux OS
            
        break;
        
        case "mac":
            //Mac OS
            
        break;
        
        case "iph":
            //Iphone OS
            
        break;
    }
    
    consoleNativeProcess.exit();
}

所以代码应该非常简单。它可能并不全部存在，因为我刚刚复制了处理本机进程启动、输出和终止的代码部分。然后我删除了部分敏感代码。基本上，您只是获取操作系统信息，导航到可执行文件的路径，检查它是否存在，如果存在，则启动它，对其运行命令并等待输出。我在处理输出时也放入了一个 switch 语句来检查操作系统，因为可以安全地假设您接下来对输出所做的操作也将取决于操作系统（或者至少在我的情况下是这样）。如果您需要更多帮助来理解这一切，我建议您在 Google 上搜索有关 Adobe AIR Native Process API 的教程，或者在此处发布更多问题。 :)