如何使用事件侦听器来加载动画片段的循环

Question

我希望场景加载5个不同的影片剪辑（名为B1-B5）。每个影片剪辑都放在特定的x和y上。每个影片剪辑在翻转/展开时增长/缩小....

我通过输入所有内容并且每次都复制每个部分来使代码工作，但它很混乱，我想通过循环来执行它来清理代码（如果可能的话？）。

这是有效的代码，但我必须为每个影片剪辑复制它（更改明显的位）...

var scene1:MovieClip = new B1();
    addChild(scene1);
    scene1.x = 170.30;
    scene1.y = 231.15;
    scene1.addEventListener(MouseEvent.MOUSE_OVER, onRollOverEvent1);
    scene1.addEventListener(MouseEvent.MOUSE_OUT, onRollOutEvent1);

function onRollOverEvent1(e:MouseEvent) {
    scene1.width=25.9;
    scene1.height=25;
 }

function onRollOutEvent1(e:MouseEvent) {
    scene1.width = 20.9;
    scene1.height = 20;
 }

以下是我尝试过的但是已经被困住了一段时间......

for (var i:int=1; i<5; i++){
    var scene[i]:MovieClip = new "B"+i();
    addChild("scene"+i);
    //var scene[i]:MovieClip = new B[i]();
    scene[i].addEventListener(MouseEvent.MOUSE_OVER, onRollOverEvent);
    scene[i].addEventListener(MouseEvent.MOUSE_OUT, onRollOutEvent)

    function onRollOverEvent(e:MouseEvent) {
    scene[i].width=25.9;
    scene[i].height=25;
 }
    function onRollOutEvent(e:MouseEvent) {
    scene[i].width = 20.9;
    scene[i].height = 20;
 }
}

scene1.x = 170.30;
scene1.y = 231.15;
scene2.x = 284.30;
scene2.y = 250.75;
scene3.x = 377.30;
scene3.y = 280.15;  
scene4.x = 444.30;
scene4.y = 321.15;
scene5.x = 196.30;
scene5.y = 172.15;

Answer 1

首先，让我们来看看你的错误。

new "B"+i();

最好的是转换为将数字i作为函数调用并将结果作为字符串添加到“B”。但即使是新的“B1”（）也与新的B1（）不同。事实上，有一个方法getDefinitionByName（..）允许通过其名称来解决一个类，但我不建议使用它，因为它是高级主题。

var scene[i]:MovieClip

你不能用这种方式定义变量scene1，scene2等。你可以设计的最接近的东西是方括号表示法：这个[“scene”+ i] = ....

addChild("scene"+i);

参数必须是DisplayObject实例，而不是String。

for (...)
{
    ...
    function onRollOverEvent(e:MouseEvent)
    ...
}

不要在其他函数或循环中定义函数。

scene[i].width = 20.9;
scene[i].height = 20;

在循环结束时，我将等于5，那么，您认为这样的记录会解决什么？

然后，解决方案。

当您将工作解决方案扩展到多个实例时，您将采用算法。循环和数组是你的朋友。

// Lets devise a list of classes and (x,y) coordinates.
var Designs:Array = [
    null, // the 0-th element
    {id:B1, x:170, y:230},
    {id:B2, x:285, y:250},
];

for (var i:int = 1; i < Design.length; i++)
{
    // Retrieve a record for the future object.
    var aDesign:Object = Designs[i];

    // Get a reference to the object's class.
    var aClass:Class = aDesign.id;

    // Create the object. Yes, you CAN omit () with
    // the "new" operator if there are no mandatory arguments.
    var aThing:Movieclip = new aClass;

    // Set coordinates from the design record.
    aThing.x = aDesign.x;
    aThing.y = aDesign.y;

    // Add to the display list.
    addChild(aThing);

    // Subscribe the event handlers.
    aThing.addEventListener(MouseEvent.MOUSE_OVER, onOver);
    aThing.addEventListener(MouseEvent.MOUSE_OUT, onOut);

    // Save the object's reference for the later use.
    // If you'd need to address, say, 3rd object,
    // you do it as following:
    // Designs[3].instance
    aDesign.instance = aThing;
}

function onOver(e:MouseEvent):void
{
    // You subscribed all of the objects to this one event handler.
    // This is the correct way to learn, which one of the objects
    // is under the mouse and is dispatching the said event.
    var aThing:MovieClip = e.currentTarget as MovieClip;

    // Change the object's size.
    aThing.width = 26;
    aThing.height = 25;
}

function onOut(e:MouseEvent):void
{
    // Get the source of the dispatched event.
    var aThing:MovieClip = e.currentTarget as MovieClip;

    // Change the object's size.
    aThing.width = 21;
    aThing.height = 20;
}