访问类 构建宏中的Context.getLocalClass（）

Question

我想创建一个宏，为我的类添加一个字段，字段值应该是他们所在的类的Class<T>。这是我的最小示例，并且它不会使用此错误进行编译：

src / Base.hx：3：字符2-11：未知标识符：foo.Foo

但是，如果我将Foo从包foo移动到root包，那么它就可以编译并运行。

Main.hx

import foo.Foo;
class Main 
{
    static function main() 
    {
        trace(Foo.data);
    }
}

Build.hx

import haxe.macro.Context;
import haxe.macro.Type;
import haxe.macro.Expr;

class Build
{
    macro static public function build(DataClass):Array<Field> 
    {
        var cls = Context.getLocalClass().get();
        var pack = cls.pack.concat([cls.name]);
        var name = pack.join(".");
        trace(name);

        var expr = {
            expr: ExprDef.EConst(Constant.CIdent(name)),
            pos: Context.currentPos()
        }

        var newFieldCls = macro class {

            public static var data:Class<Dynamic> = $expr; 

        }

        var fields = Context.getBuildFields();
        return fields.concat(newFieldCls.fields);


    }
}

Base.hx

package;

@:autoBuild(Build.build(Main.Data))
class Base
{
    public function new()
    {
    }
}

富/ Foo.hx

package foo;

class Foo extends Base
{
}

Answer 1

EConst(CIdent("foo.Bar"))将不起作用，因为这非常像你可以在其中指定一个带有.句点的名称。相反，你需要做EField({ expr: EConst(CIdent("foo")) }, "Bar")，因为这是foo.Bar被编译器本身解析的（尝试从宏中的traceing表达式）。

所以正确的代码就是

import haxe.macro.Context;
import haxe.macro.Expr;
class Build {
    public static macro function build():Array<Field> {
        var self = Context.getLocalClass().get();
        var cpos = Context.currentPos();
        var out:Expr = null;
        inline function add(name:String) {
            if (out == null) {
                out = { expr: EConst(CIdent(name)), pos: cpos };
            } else out = { expr: EField(out, name), pos: cpos };
        }
        for (name in self.pack) add(name);
        add(self.name);
        return Context.getBuildFields().concat((macro class {
            public static var data:Class<Dynamic> = $out;
        }).fields);
    }
}

处理EConst(CIdent)表达式的创建，然后将其包装在EField层中，用于尾随包，最后是类名。