Gnuplot 在多行文本周围放置黑色边框

Question

我想在绘图上显示的一些文本信息周围放置黑色边框。而我还没有成功。文本信息以 2 列显示。第一列与文本右对齐，第二列与数值左对齐。框末尾的数字值似乎没有完全左对齐。这是我使用的代码：

这与 4 年前提出但尚未得到答案的另一个问题有些相关：

“设置标签”命令末尾的 GNUPLOT 屏幕位置

reset session

mean = 1.85
variance = 961.67
median = 23.12
lowQuartile = .23
upQuartile = 2.25

set yrange[0:1]
set xrange[0:1]

infostat = sprintf("Mean :  \nVariance :  \nMedian :  \nFirst Quartile :  \nThird Quartile :  ") 
infonumber = sprintf(" %6.2f\n %6.2f\n %6.2f\n %6.2f\n %6.2f", mean, variance, median, lowQuartile, upQuartile)
 
set style textbox 2 opaque fc rgb 0xffff00 noborder
set style textbox 3 transparent fc rgb 0xffff00 border lc "black"

set label 10 infostat at graph .6,.8 right boxed bs 2 front
set label 11 infonumber at graph .6,.8 left boxed bs 2 front

plot NaN notitle

Answer 1

关于列中的文本对齐方式，使用等宽字体可能是最简单的。我有一个关于比例字体空间的“相关问题”。 gnuplot 似乎很难从使用的图形库中获取确切的空间。因此，任何使用比例字体来很好地对齐数字的尝试很可能会失败，因为空间取决于数字本身。请参阅下面示例中的标签 3 和 4。 因此，我对“表格”标签的建议是：使用等宽字体。

脚本：

### text and number alignment in textbox
reset session

mean = 1.85
variance = 961.67
median = 23.12
lowQuartile = .23
upQuartile = 2.25

set yrange[0:1]
set xrange[0:1]

fmt  = "% 14s :% 7.2f"
info = sprintf(fmt."\n".fmt."\n".fmt."\n".fmt."\n".fmt, \
               "Mean", mean, "Variance", variance, "Median", median, \
               "First Quartile", lowQuartile, "Third Quartile", upQuartile)

set style textbox 1 opaque fc rgb 0xffcccc margin 4,4
set style textbox 2 opaque fc rgb 0xccffcc margin 4,4

set label 1 info at graph 0.2,0.8 boxed bs 1 font "Arial"
set label 2 info at graph 0.6,0.8 boxed bs 2 font "Courier New"

set label 3 "1111111.1111111\n2222222.2222222" at graph 0.4,0.4 right font "Arial"
set label 4 "1111111.1111111\n2222222.2222222" at graph 0.8,0.4 right font "Courier New"

plot NaN notitle
### end of script

结果：

（来自wxt终端）