语法正则表达式独立匹配，但不匹配

Question

这是我为解决每周挑战“实施括号扩展”所做的尝试。我在语法下面写了，应该能用。但不是。

grammar BraceExpansion
{
    regex TOP          { <start-txt> <to-expand> <end-txt> }
    regex start-txt    { <save-char>* }
    regex end-txt      { <save-char>* }
    token save-char    { <-[ \" \& \( \) \` \' \; \< \> \| ]> }
    token list-element { <-[ \" \! \$ \& \( \) \` \' \; \< \> \| ]> }
    token alphanum     { <[ a..z A..Z 0..9 ]> }
    token alpha        { <[ a..z A..Z ]> }
    regex num          { \-? <[ 0..9 ]>+ }
    regex to-expand    { <range> | <list>  }
    regex range        { <alpha-range> | <num-range> }
    regex num-range    { \{ <num>  \. \. <num> [ \. \. <num> ]? \} }
    regex alpha-range  { \{ <alpha> \. \. <alpha> [ \. \.<num> ]? \} }
    regex list         { \{ <list-element>+ % ',' \} }
}

say brace-expand( 'A{1..3}B{a..g..3}C{1,2}D' );

sub num-range( $match )
{
    say "-NUM-";
    my @num = |$match<range><num-range><num>.list>>.Int;
    my @range = @num[0] ... @num[1];
    my $steps = ( @num[2] // 1 ).abs;
    @range.batch( $steps )>>.[0];
}


sub alpha-range( $match )
{
    say "-ALPHA-";
    my @num = |$match<range><alpha-range><alpha>.list>>.Str;
    my @range = @num[0] ... @num[1];
    my $steps = ( $match<range><alpha-range><num> // 1 ).abs;
    @range.batch($steps)>>.[0];
}

sub list( $match )
{
    say "-LIST-";
    $match<list><list-element>.list>>.Str;
}

sub brace-expand( $str )
{
    say "brace-expand( $str )";

    my $match = BraceExpansion.parse( $str );

    my @alternatives =
        $match<range><num-range>   ?? num-range( $match )   !!
        $match<range><alpha-range> ?? alpha-range( $match ) !!
        $match<list>               ?? list( $match )        !!
        ();

    say "A", @alternatives;

    return $str
        unless @alternatives;

    @alternatives
         .map( -> $element { $match<start-txt>.Str ~ $element ~ $match<end-txt>.Str } )
         .map( -> $result  { brace-expand( $result ) } )
    ;
}

但是，如果我将TOP规则更改为

    regex TOP          { <start-txt> <range> <end-txt> }

或

    regex TOP          { <start-txt> <list> <end-txt> }

range和list令牌独立工作，我得到了期望的输出。但是，当我使用to-expand规则时，整个语法不匹配，我无法弄清楚原因。改错了吗？但是，如果是这样，为什么<alpha-range> | <num-range>起作用？

....（时间流逝）....

与此同时，我发现了

regex TOP           { <start-txt> [ <range> | <list> ] <end-txt> } 

做我想要的。但是我的问题仍然存在，为什么它不能像上面那样工作？

Answer 1

比赛进行得很好；您没有正确索引到匹配项中。结果匹配的结构是：

start-txt => ｢A{1..3}B{a..g..3}C｣
  save-char => ｢A｣
  ...
to-expand => ｢{1,2}｣
  list => ｢{1,2}｣  # (or range)
  ...
end-txt => ｢D｣
  save-char => ｢D｣
  ...