如何在IDL中的数组内存储数组？

Question

我试图在IDL中的二维数组中存储一组1维IDL数组。我找不到关于Harris地理空间的任何文档，我没有运气只是乱用语法。

一个三维数组似乎是一个明显的解决方案，但我需要存储的1D数组的长度长度从1到800个整数不等，因此我将使用很少的3D数组。

任何指针都非常赞赏。谢谢。

Answer 1

你的陈述，

任何指针都非常赞赏

考虑到你的问题的一个可能的解决方案是使用指针，这有点讽刺！据我所知，这是在单个数组中存储可变长度数组的唯一方法。基本上，指针只是变量，但它们不包含数据，而是包含指向数据存储在内存中的指针。

您可以使用PTR_NEW函数创建指针：

IDL> p = ptr_new(findgen(5))                                                                                                                                      
IDL> help, p                                                                                                                                                      
P               POINTER   = <PtrHeapVar22> 

要“取消引用”指针（即访问数据），您需要使用星号：

IDL> print, p                                                                                                                                                     
<PtrHeapVar22>                                                                                                                                                    
IDL> print, *p                                                                                                                                                          
0.00000      1.00000      2.00000      3.00000      4.00000 

所以，你需要的是一个PTRARR（指针数组）：

IDL> test_arr = ptrarr(2,3,/ALLOCATE_HEAP)                                                                                                                        
IDL> help, test_arr                                                                                                                                               
TEST_ARR        POINTER   = Array[2, 3] 

其中数组的每个元素都是您的1-D数组之一。您可以通过存储指针来填充数组：

IDL> test_arr[0,0] = p                                                                                                                                            
IDL> print, *test_arr[0,0]                                                                                                                                              
0.00000      1.00000      2.00000      3.00000      4.00000 

或者通过将数组分配给指针数组的解除引用元素：

IDL> *test_arr[0,1] = randomu(seed, 4)                                                                                                                            
IDL> print, *test_arr[0,1]                                                                                                                                             
0.838449     0.967399    0.0669304     0.101592

使用指针的一个缺点是你会失去很多（如果不是全部）普通IDL数组的优秀矢量化优势。也就是说，您通常需要遍历数组的元素以访问存储在指针中的值，这意味着您将获得性能损失。需要注意的另一件事是运算符优先级如何影响解除引用运算符（星号）的使用。例如，如果将结构存储在指针中，则需要以下列方式使用括号来访问结构中的数据：

IDL> str = {a:1,b:'x'}                                                                                                                                                                                                                                                                             
IDL> str_ptr = ptr_new(str)                                                                                                                                                                                                                                                                                                                                                                                                            
IDL> print, (*str_ptr).a                                                                                                                                                 
1   

否则你会收到一个错误：

IDL> print, *str_ptr.a                                                                                                                                            
% Expression must be a structure in this context: STR_PTR.                                                                                                        
% Execution halted at: $MAIN$  

这是documentation供进一步参考。