我是SPARQL的新手,我正在尝试根据主题的内容选择属性。例如,使用下面的RDF数据,我想返回包含“var2_1”的结果:
<rdf:Description rdf:about="http://www.ontologydesignpatterns.org/ont/fred/domain.owl#var0">
<rdf:type rdf:resource="http://www.ontologydesignpatterns.org/ont/fred/domain.owl#var2_0"/>
</rdf:Description>
<rdf:Description rdf:about="http://www.ontologydesignpatterns.org/ont/fred/domain.owl#var1">
<rdf:type rdf:resource="http://www.ontologydesignpatterns.org/ont/fred/domain.owl#var2_1"/>
</rdf:Description>
这是我正在编写的查询,但它什么也没有返回,我似乎无法找到指定主题应包含“var1”的方法:
SELECT ?t
WHERE {
?s rdf:type ?t
FILTER regex(?s, "var1")
}
我希望以正确的方式帮助你做到这一点。
主题不是字符串文字值,而是IRI:http://www.ontologydesignpatterns.org/ont/fred/domain.owl#var1
。要匹配这一点,您不应该使用正则表达式,而是使用实际的IRI本身:
SELECT ?t
WHERE {
?s rdf:type ?t
FILTER(?s = <http://www.ontologydesignpatterns.org/ont/fred/domain.owl#var1>)
}
或更简洁:
SELECT ?t
WHERE {
<http://www.ontologydesignpatterns.org/ont/fred/domain.owl#var1> rdf:type ?t
}
另一个答案已经指出你的?s
是一个URI,应该直接匹配而不是使用正则表达式。此外,值得记住的是,如果您定义了正确的前缀,匹配特定的URI会变得更加简单。如果我们为文件的URI定义前缀,那么实际的查询模式会变得更简单:
PREFIX fred: <http://www.ontologydesignpatterns.org/ont/fred/domain.owl#>
SELECT ?t
WHERE {
fred:var1 rdf:type ?t
}
查询可以变得更简单:rdf:type
有一个内置缩写“a
”,WHERE
关键字是可选的:
PREFIX fred: <http://www.ontologydesignpatterns.org/ont/fred/domain.owl#>
SELECT ?t {
fred:var1 a ?t
}
最后,如果您真的想使用正则表达式来匹配URI,可以通过使用str
将URI转换为字符串来实现:
SELECT ?t {
?s a ?t
FILTER regex(str(?s), "var1")
}
但与其他选项相比,在较大的数据集上这将非常慢。
最后,为了支持AKSW的评论,这里是从RDF / XML转换为Turtle的文件:
PREFIX fred: <http://www.ontologydesignpatterns.org/ont/fred/domain.owl#>
fred:var0 a fred:var2_0.
fred:var1 a fred:var2_1.