约束表示约束

Question

如何将Haskell中的约束含义编码为新约束？在我的示例中，我想要求每个Functor c d f都必须使Obj c x隐含为Obj c (f x)。我正在写约束forall x . Obj c x => Obj d (f x)。

{-# LANGUAGE AllowAmbiguousTypes       #-}
{-# LANGUAGE KindSignatures            #-}
{-# LANGUAGE MultiParamTypeClasses     #-}
{-# LANGUAGE RankNTypes                #-}
{-# LANGUAGE ScopedTypeVariables       #-}
{-# LANGUAGE TypeApplications          #-}
{-# LANGUAGE TypeFamilies              #-}
{-# LANGUAGE QuantifiedConstraints     #-}

import Prelude hiding (id, Functor, fmap)
import Data.Kind

class Category c where                            
  type Obj c a :: Constraint                    
  id :: (Obj c x) => c x x                        
  comp :: (Obj c x) => c y z -> c x y -> c x z    

class ( Category c, Category d, forall x . Obj c x => Obj d (f x))
      => Functor c d f where
  fmap :: (Obj c x, Obj c y) => c x y -> d (f x) (f y)

doublefmap :: forall c f x . (Category c , Functor c c f, Obj c x)
           => c x x -> c (f (f x)) (f (f x))
doublefmap = fmap @c @c @f . fmap @c @c @f

但是这会产生以下错误：

Minimal.hs:27:14: error:
    • Could not deduce: Obj c (f x) arising from a use of ‘fmap’
      from the context: (Functor c c f, Obj c x)
        bound by the type signature for:
                   doublefmap :: forall (c :: * -> * -> *) (f :: * -> *) x.
                                 (Category c, Functor c c f, Obj c x) =>
                                 c x x -> c (f (f x)) (f (f x))
        at Minimal.hs:(25,1)-(26,44)
    • In the first argument of ‘(.)’, namely ‘fmap @c @c @f’
      In the expression: fmap @c @c @f . fmap @c @c @f
      In an equation for ‘doublefmap’:
          doublefmap = fmap @c @c @f . fmap @c @c @f
    • Relevant bindings include
        doublefmap :: c x x -> c (f (f x)) (f (f x))
          (bound at Minimal.hs:27:1)

我在这里做错了什么？我还应该给编译器什么提示？有没有更好的方法可以实现这一目标？

我的猜测是，我需要使用Data.Constraint和:-，但是如何使用？

Answer 1

以下内容似乎可行，但我不知道这是否是一种更简单的方法。它使用(\\)中的运算符Data.Constraint。

{-# LANGUAGE AllowAmbiguousTypes       #-}
{-# LANGUAGE KindSignatures            #-}
{-# LANGUAGE MultiParamTypeClasses     #-}
{-# LANGUAGE RankNTypes                #-}
{-# LANGUAGE ScopedTypeVariables       #-}
{-# LANGUAGE TypeApplications          #-}
{-# LANGUAGE TypeFamilies              #-}
{-# LANGUAGE TypeOperators             #-}
{-# LANGUAGE FlexibleContexts          #-}
{-# LANGUAGE QuantifiedConstraints     #-}

import Prelude hiding (id, Functor, fmap)
import Data.Constraint

class Category c where                            
  type Obj c a :: Constraint
  id :: (Obj c x) => c x x
  comp :: (Obj c x) => c y z -> c x y -> c x z    

class (Category c, Category d) => Functor c d f where
  fobj :: forall x. Obj c x :- Obj c (f x)
  fmap :: (Obj c x, Obj c y) => c x y -> d (f x) (f y)

doublefmap :: forall c f x . (Category c , Functor c c f, Obj c x)
           => c x x -> c (f (f x)) (f (f x))
doublefmap = (fmap @c @c @f . fmap @c @c @f) \\ fobj @c @c @f @x

Answer 2

这是第二个解决方案，不使用（至少对我来说）Data.Constraint似乎更优雅。

{-# LANGUAGE AllowAmbiguousTypes           #-}
{-# LANGUAGE KindSignatures            #-}
{-# LANGUAGE MultiParamTypeClasses     #-}
{-# LANGUAGE RankNTypes                #-}
{-# LANGUAGE ScopedTypeVariables       #-}
{-# LANGUAGE TypeApplications          #-}
{-# LANGUAGE TypeFamilies              #-}
{-# LANGUAGE TypeOperators              #-}
{-# LANGUAGE FlexibleContexts              #-}
{-# LANGUAGE QuantifiedConstraints      #-}
{-# LANGUAGE ConstraintKinds           #-}

import Prelude hiding (id, Functor, fmap)

class Category objc c where                            
  id :: (objc x) => c x x
  comp :: (objc x) => c y z -> c x y -> c x z

class (Category objc c, Category objd d, forall x . (objc x) => objd (f x))
      => Functor objc c objd d f where
  fmap :: (objc x, objc y) => c x y -> d (f x) (f y)

doublefmap :: forall c f x objc objd . (Category objc c , Functor objc c objc c f, objc x)
           => c x x -> c (f (f x)) (f (f x))
doublefmap = (fmap @objc @c @objc @c @f . fmap @objc @c @objc @c @f) 

如果有人可以改善我会很高兴。