从资源文件加载的透明PNG图像，使用Grapics32调整大小并在画布上绘制

Question

bounty过期在3小时内。该问题的答案有资格获得+ 300声望赏金。Marus Nebunu正在寻找规范答案：“我需要那种透明度....”

我需要一点帮助...

我的应用程序资源中有一个透明的PNG图像。到目前为止，我一直将其加载到TPngImage中，并使用Canvas.Draw(X, Y, PngImage);在屏幕上绘制它。它是透明绘制的。现在，我将应用程序更新为DpiAware，并且需要缩放所有图像。我需要一个高质量的重采样器，并且选择使用Graphics32。我设法进行了重采样，但是我不知道如何保持透明性。 。

Foto32, Buff: TBitmap32;
FotoPng: TPngImage;

constructor TForm.Create(AOwner: TComponent);
const BkgHeight = 380;
var Res: TKernelResampler;
    SRect, DRect: TRect;
    ImgWidth: Integer;
begin
 inherited;
 Buff:= TBitmap32.Create;
 Res:= TKernelResampler.Create;
 Res.Kernel:= TLanczosKernel.Create;

 FotoPng:= TPngImage.Create;
 FotoPng.Transparent:= True;
 FotoPng.TransparentColor:= clBlack;
 FotoPng.LoadFromResourceName(HInstance, 'BKG_FOTO');
 Foto32:= TBitmap32.Create;
 Foto32.DrawMode:= dmBlend;
 Foto32.CombineMode:= cmMerge;
 Foto32.OuterColor:= clBlack;
 Foto32.Canvas.Brush.Style:= bsClear;
 Foto32.SetSize(FotoPng.Width, FotoPng.Height);
 FotoPng.Draw(Foto32.Canvas, Rect(0, 0, FotoPng.Width, FotoPng.Height));

 ImgWidth:= Round(Real(Foto32.Width / Foto32.Height) * BkgHeight);
 SRect:= Rect(0, 0, Foto32.Width, Foto32.Height);
 Buff.DrawMode:= dmBlend;
 Buff.CombineMode:= cmMerge;
 Buff.OuterColor:= clBlack;
 Buff.Canvas.Brush.Style:= bsClear;
 Buff.SetSize(Scale(ImgWidth), Scale(BkgHeight));
 DRect:= Rect(0, 0, Buff.Width, Buff.Height);
 Res.Resample(Buff, DRect, DRect, Foto32, SRect, dmTransparent {dmBlend}, nil);
end;

procedure TForm.Paint;
begin
 // ....
 Buff.DrawTo(Canvas.Handle, X, Y);
end;

这是我的透明PNG图片，已编译为资源：https://postimg.cc/3yy3wrJB

我在这里找到了similar question，但是我没有将图像与TImage一起使用，而是直接将其绘制在画布上。在单个答案中，David说：

无论如何，我会结合以下方面的透明性支持：具有TBitmap32重采样功能的TImage构建解决方案那样。将原始图像保留在TBitmap32实例中。每当您需要将其加载到TImage组件中，例如调整大小，请使用TBitmap32执行内存中调整大小并加载调整尺寸的图片。

这正是我要尝试做的，但我不知道为什么透明效果不起作用。有任何想法吗 ？

Answer 1

您的问题似乎是将缓冲区绘制到屏幕上的问题。 Bitmap32使用StretchDIBits进行绘制，而忽略了Alpha通道。

您可以使用AlphaBlend功能来绘制图像：

procedure TForm1.FormPaint(Sender: TObject);
var
  BF: TBlendFunction;
begin
  BF.BlendOp := AC_SRC_OVER;
  BF.BlendFlags := 0;
  BF.SourceConstantAlpha := 255;
  BF.AlphaFormat := AC_SRC_ALPHA;

  Winapi.Windows.AlphaBlend(Canvas.Handle, 0, 0, Buff.Width, Buff.Height,
    Buff.Canvas.Handle, 0, 0, Buff.Width, Buff.Height, BF);
end;

或将您的TBitmap32转换为Delphi TBitmap并使用VCL进行绘制：

procedure TForm1.FormPaint(Sender: TObject);
var
  Bmp: TBitmap;
  I: Integer;
begin
  Bmp := TBitmap.Create;
  try
    Bmp.PixelFormat := pf32bit;
    Bmp.AlphaFormat := afDefined;
    Bmp.SetSize(Buff.Width, Buff.Height);
    for I := 0 to Buff.Height - 1 do
      Move(Buff.ScanLine[I]^, Bmp.ScanLine[I]^, Buff.Width * 4);
    Canvas.Draw(0, 0, Bmp);
  finally
    Bmp.Free;
  end;
end;