删除命名空间并替换为另一个命名空间

问题描述 投票：0回答：2

我的输出有名称空间，但应删除它并替换为另一个名称空间。这可能吗？

目前，我有一个XSL：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
xmlns:wd="urn:com.workday.report/INT001"
xmlns:pi="urn:com.workday.report/INT001"
xmlns:xs="http://www.w3.org/2001/XMLSchema">

<xsl:output indent="yes" method="xml" omit-xml-declaration="yes"/>
<xsl:strip-space elements="*" />

<xsl:template match="wd:RD">
    <pi:PEE>
        <xsl:for-each-group select="wd:RE" group-by="wd:PG">
            <pi:PG>
                <pi:X>
                    <pi:PGID><xsl:value-of select="wd:PGID"/></pi:PGID>
                    <pi:DF><xsl:value-of select="current-dateTime() - xs:dayTimeDuration('P1D')"/></pi:DF>
                    <pi:DE><xsl:value-of select="current-dateTime()"/></pi:DE>
                </pi:X>
                <xsl:for-each select="current-group()">
                <xsl:call-template name="Content"/>                    
                </xsl:for-each>
            </pi:PG>
        </xsl:for-each-group>
    </pi:PEE>
</xsl:template>

<xsl:template name="Content">
<pi:EE>  
    <pi:L1>
        <pi:EID><xsl:value-of select="wd:EID"/></pi:EID>
        <pi:PGID><xsl:value-of select="wd:PGID"/></pi:PGID>
        <pi:PG><xsl:value-of select="wd:PG"/></pi:PG>
    </pi:L1>
    <pi:L2>
        <pi:EE><xsl:value-of select="wd:EE"/></pi:EE>
        <pi:BD><xsl:value-of select="wd:BD"/></pi:BD>
        <pi:GDR><xsl:value-of select="wd:GDR"/></pi:GDR>
    </pi:L2>
</pi:EE>  
</xsl:template>
</xsl:stylesheet>

和XML：

<wd:RD xmlns:wd="urn:com.workday.report/INT001">
<wd:RE>
<wd:PG>AR</wd:PG>
<wd:PGID>10102</wd:PGID>
<wd:EID>0001</wd:EID>
<wd:EE>Emp1</wd:EE>
<wd:GDR>M</wd:GDR>
<wd:BD>1900-01-01</wd:BD>
</wd:RE>
<wd:RE>
<wd:PG>OR</wd:PG>
<wd:PGID>10101</wd:PGID>
<wd:EID>0002</wd:EID>
<wd:EE>Emp2</wd:EE>
<wd:GDR>F</wd:GDR>
<wd:BD>1900-02-02</wd:BD>
</wd:RE>
<wd:RE>
<wd:PG>OR</wd:PG>
<wd:PGID>10101</wd:PGID>
<wd:EID>0003</wd:EID>
<wd:EE>Emp3</wd:EE>
<wd:BD>1900-03-03</wd:BD>
</wd:RE>
</wd:RD>

我想要的输出是：

<pi:PEE xmlns:pi="urn:com.workday/picof">
<pi:PG>
   <pi:X>
     <pi:PCID>101</pi:PCID>
     <pi:PGID>10101</pi:PGID>
  </pi:X>
  <pi:EE>
     <pi:L1>
        <pi:EID>0002</pi:EID>
        <pi:PGID>10101</pi:PGID>
        <pi:PG>OR</pi:PG>
     </pi:L1>
     <pi:L2>
        <pi:EE>Emp2</pi:EE>
        <pi:BD>1900-02-02</pi:BD>
        <pi:GDR>F</pi:GDR>
     </pi:L2>
  </pi:EE>
  <pi:EE>
     <pi:L1>
        <pi:EID>0003</pi:EID>
        <pi:PGID>10101</pi:PGID>
        <pi:PG>OR</pi:PG>
     </pi:L1>
     <pi:L2>
        <pi:EE>Emp3</pi:EE>
        <pi:BD>1900-03-03</pi:BD>            
     </pi:L2>
  </pi:EE>
</pi:PG>
<pi:PG>
  <pi:X>
     <pi:PCID>102</pi:PCID>
     <pi:PGID>10102</pi:PGID>
  </pi:X>
  <pi:EE>
     <pi:L1>
        <pi:EID>0001</pi:EID>
        <pi:PGID>10102</pi:PGID>
        <pi:PG>AR</pi:PG>
     </pi:L1>
     <pi:L2>
        <pi:EE>Emp1</pi:EE>
        <pi:BD>1900-01-01</pi:BD>
        <pi:GDR>M</pi:GDR>
     </pi:L2>
  </pi:EE>
</pi:PG>
</pi:PEE>

我想删除xmlns:wd="urn:com.workday.report/INT001" xmlns:pi="urn:com.workday.report/INT001" xmlns:xs="http://www.w3.org/2001/XMLSchema"并被xmlns:pi="urn:com.workday/picof"取代

此外，如果您注意到，也应删除任何空白元素。对于Emp3，GDR是空的。

xml xslt xslt-2.0
2个回答
0
投票

我认为您可以通过使用xpath-default-namespace简单地缩短代码，然后，因为您只想输出存在的那些输入元素的结果元素，您可以根据需要使用apply-templates将输入元素映射到带有模板的结果元素：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xpath-default-namespace="urn:com.workday.report/INT001"
    xmlns:pi="urn:com.workday/picof"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="RD">
      <pi:PEE>
          <xsl:for-each-group select="RE" group-by="PG">
              <pi:PG>
                  <pi:X>
                    <pi:PGID><xsl:value-of select="PGID"/></pi:PGID>
                    <pi:DF><xsl:value-of select="current-dateTime() - xs:dayTimeDuration('P1D')"/></pi:DF>
                    <pi:DE><xsl:value-of select="current-dateTime()"/></pi:DE>
                  </pi:X>
                  <xsl:apply-templates select="current-group()"/>
              </pi:PG>
          </xsl:for-each-group>
      </pi:PEE>
  </xsl:template>

  <xsl:template match="RE">
      <pi:EE>
          <pi:L1>
              <xsl:apply-templates select="EID, PGID, PG"/>
          </pi:L1>
          <pi:L2>
              <xsl:apply-templates select="EE, BD, GDR"/>
          </pi:L2>
      </pi:EE>
  </xsl:template>

  <xsl:template match="RE/*">
      <xsl:element name="pi:{local-name()}">
          <xsl:apply-templates/>
      </xsl:element>
  </xsl:template>

</xsl:stylesheet>

这会将您在https://xsltfiddle.liberty-development.net/6qVRKwH上的输入转换为结果

<pi:PEE xmlns:pi="urn:com.workday/picof">
   <pi:PG>
      <pi:X>
         <pi:PGID>10102</pi:PGID>
         <pi:DF>2018-09-16T17:49:47.15+02:00</pi:DF>
         <pi:DE>2018-09-17T17:49:47.15+02:00</pi:DE>
      </pi:X>
      <pi:EE>
         <pi:L1>
            <pi:EID>0001</pi:EID>
            <pi:PGID>10102</pi:PGID>
            <pi:PG>AR</pi:PG>
         </pi:L1>
         <pi:L2>
            <pi:EE>Emp1</pi:EE>
            <pi:BD>1900-01-01</pi:BD>
            <pi:GDR>M</pi:GDR>
         </pi:L2>
      </pi:EE>
   </pi:PG>
   <pi:PG>
      <pi:X>
         <pi:PGID>10101</pi:PGID>
         <pi:DF>2018-09-16T17:49:47.15+02:00</pi:DF>
         <pi:DE>2018-09-17T17:49:47.15+02:00</pi:DE>
      </pi:X>
      <pi:EE>
         <pi:L1>
            <pi:EID>0002</pi:EID>
            <pi:PGID>10101</pi:PGID>
            <pi:PG>OR</pi:PG>
         </pi:L1>
         <pi:L2>
            <pi:EE>Emp2</pi:EE>
            <pi:BD>1900-02-02</pi:BD>
            <pi:GDR>F</pi:GDR>
         </pi:L2>
      </pi:EE>
      <pi:EE>
         <pi:L1>
            <pi:EID>0003</pi:EID>
            <pi:PGID>10101</pi:PGID>
            <pi:PG>OR</pi:PG>
         </pi:L1>
         <pi:L2>
            <pi:EE>Emp3</pi:EE>
            <pi:BD>1900-03-03</pi:BD>
         </pi:L2>
      </pi:EE>
   </pi:PG>
</pi:PEE>

这对于pi:PG元素有不同的顺序，但你没有解释为什么你的结果的元素顺序与相应的输入元素不同，我没有看到你发布的XSLT中有任何改变顺序的尝试，所以我发布了这个作为建议，如果订单不正确，您需要编辑您的问题并解释您想要以何种方式重新排序或排序您创建的组。

1
投票

要删除额外的命名空间，只需在样式表声明中添加exclude-result-prefixes="wd xs"：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
    xmlns:wd="urn:com.workday.report/INT001"
    xmlns:pi="urn:com.workday.report/INT001"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="wd xs">

另外，为了删除空元素，可以添加如下条件，首先检查该元素是否包含数据而不是复制元素。

<xsl:if test="wd:GDR[node()]"><pi:GDR><xsl:value-of select="wd:GDR"/></pi:GDR></xsl:if>
最新问题
© www.soinside.com 2019 - 2024. All rights reserved.