如何使用Put_Line方法输出整数？

Question

我无法编译这个程序，因为它似乎没有在Put_Line方法中打印整数变量和字符串。我已经在线查看了源代码，当它们这样做时它可以工作，所以我哪里出错了。谢谢你的帮助。

with Ada.Text_IO;                       use Ada.Text_IO;
with Ada.Integer_Text_IO;           use Ada.Integer_Text_IO;

procedure MultiplicationTable is

    procedure Print_Multiplication_Table(Number :in Integer; Multiple :in Integer) is
        Result : Integer;   
    begin
        for Count in 1 ..Multiple
        loop
            Result := Number * Count;
            Put_Line(Number & " x " & Count & " = " & Result);
        end loop; 
    end Print_Multiplication_Table;
    Number  :   Integer;
    Multiple    :   Integer;

begin
    Put("Display the multiplication of number: ");
    Get(Number);
    Put("Display Multiplication until number: ");
    Get(Multiple);
    Print_Multiplication_Table(Number,Multiple);
end MultiplicationTable;`

Answer 1

问题是你正在使用＆使用字符串和整数。请尝试以下方法之一：

用Number替换put参数中的Integer'Image(Number)

或者将Put_Line分解成你想要的组件;例如：

-- Correction to Put_Line(Number & " x " & Count & " = " & Result);
Put( Number );
Put( " x " );
Put( Count );
Put( " = " );
Put( Result);
New_Line(1);

Answer 2

你已经拥有with的use和Ada.Integer_Text_IO条款，但你实际上并没有使用它。

改变这个：

Put_Line(Number & " x " & Count & " = " & Result);

对此：

Put(Number); Put(" x "); Put(Count); Put(" = "); Put(Result); New_Line;

（我通常不会在一行上放多个语句，但在这种情况下它是有道理的。）

请注意，Integer'Image将非负整数与空格相对应，我总是发现它非常烦人; Ada.Integer_Text_IO.Put不这样做（除非你要求）。

您可以定义重载的"&"函数，如下所示：

function "&"(Left: String; Right: Integer) return String is
begin
    return Left & Integer'Image(Right);
end "&";

function "&"(Left: Integer; Right: String) return String is
begin
    return Integer'Image(Left) & Right;
end "&";

这将使你原来的Put_Line呼叫有效，但多个Put呼叫可能是更好的风格。

Answer 3

试试这个：

Put_Line(Integer'Image(Number) & " x " & Integer'Image(Count) & " = " & Integer'Image(Result));

Answer 4

基于Keith Thompson的答案（以及另一个问题中的评论），这里是一个完整的Ada程序，可以使用&输出Put_Line的字符串和整数，但没有Integer'Image否则会提供的空格：

with Ada.Text_IO; use Ada.Text_IO;
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO;

procedure Main is

function lstrip(S: String) return String is
begin
    if S(S'First) = ' ' then
        return S(S'First+1 .. S'Last);
    else
        return S;
    end if;
end;

function "&"(Left: String; Right: Integer) return String is
begin
    return Left & lstrip(Integer'Image(Right));
end "&";

function "&"(Left: Integer; Right: String) return String is
begin
    return lstrip(Integer'Image(Left)) & Right;
end "&";

begin
   Put_Line("x=" & 42);
end Main;