excel - 分组并求和，然后分组并平均 - 数据透视表的数据透视表

Question

对于下表，我首先希望按名称和日期对值进行求和。然后使用该结果数据寻找每个月按名称分组的平均值。

看来我想采取一个数据透视表的数据透视表。尽管我对想法持开放态度，但我正在尝试使用 powerpivot。

有人知道该怎么做吗？

日期	价值	名字
12/29/23	50	史蒂芬
12/29/23	20	鲍勃
12/29/23	30	汤姆
12/28/23	5	史蒂芬
12/28/23	7	鲍勃
12/28/23	3	汤姆

Answer 1

假设根据发布的标签有

Excel Constraints

，那么这应该符合预期：

• 使用

GROUPBY()

---

• 单元格中使用的公式 F3

=LET(
     _GroupBySum, GROUPBY(HSTACK(B3:B8,D3:D8),C3:C8,SUM,0,0),
     _CombineMonthName, HSTACK(TEXT(TAKE(_GroupBySum,,1),"mmm"),INDEX(_GroupBySum,,2)),
     _Output, GROUPBY(_CombineMonthName,TAKE(_GroupBySum,,-1),AVERAGE,0,0),
     VSTACK({"Month","Name","Values"},_Output))

---

或者，

• 使用

PIVOTBY()

---

• 单元格中使用的公式 F3

=LET(
     _PivotBySum, PIVOTBY(HSTACK(B3:B8,D3:D8),,C3:C8,SUM,0,0),
     _CombineMonthName, HSTACK(TEXT(TAKE(_PivotBySum,,1),"mmm"),INDEX(_PivotBySum,,2)),
     _Output, PIVOTBY(_CombineMonthName,,TAKE(_PivotBySum,,-1),AVERAGE,0,0),
     VSTACK({"Month","Name","Values"},_Output))

---

注意：

GROUPBY()

和

PIVOTBY()

功能在

MS365

中可供 Beta 用户使用。

---