perl6 NativeCall在达尔文上找不到库

Question

我正在玩NativeCall以熟悉Perl6的那一面。当然，我首先尝试加载libstatgrab（还有什么？）。

所以我从最简单的部分开始 - 主机信息。由于还没有集群支持，它只是一个结果 - 不用担心复杂化。

代码：

#!/usr/bin/env perl6 

use v6;
use NativeCall;

enum sg_error (
        SG_ERROR_NONE                   => 0,
        SG_ERROR_INVALID_ARGUMENT       => 1,
        ...
);

class sg_error_details is repr('CStruct') {
        has int32 $.error;
        has int32 $.errno_value;
        has Str $.error_arg;
};

sub sg_init(int32 $ignore_errors) returns int32 is native('statgrab') { * };

enum sg_host_state (
        sg_unknown_configuration        => 0,
        sg_physical_host                => 1,
        sg_virtual_machine              => 2,
        sg_paravirtual_machine          => 3,
        sg_hardware_virtualized         => 4
);

class sg_host_info is repr('CStruct') {
        has Str $.os_name;
        has Str $.os_release;
        has Str $.os_version;
        has Str $.platform;
        has Str $.hostname;
        has uint32 $.bitwidth;
        has int32 $.host_state;
        has uint32 $.ncpus;
        has uint32 $.maxcpus;
        has uint64 $.uptime;
        has uint64 $.systime;
};

sub sg_get_host_info(size_t is rw) returns Pointer is native('statgrab') is symbol('sg_get_host_info_r') { * };
sub sg_free_host_info(Pointer) is native('statgrab') is symbol('sg_free_stats_buf') { * };

sub MAIN() {
    my int32 $ignore_errors = 0;
    my $error = sg_init($ignore_errors);
    if $error != SG_ERROR_NONE {
        say "Maeh: $error";
        exit 1;
    }

    my size_t $num_host_infos = 0;
    my $res = sg_get_host_info($num_host_infos);
    if $num_host_infos > 0 {
        my $host_info = nativecast(sg_host_info, $res);
        with $host_info {
            say "You're using ", $_.os_name, " on ", $_.hostname;
        }
    }
    sg_free_host_info($res);
}

启动它（哑）会导致加载库错误：

$ perl6 statgrab.p6
Cannot locate native library 'libstatgrab.dylib': dlopen(libstatgrab.dylib, 1): image not found
  in method setup at /Users/sno/rakudo/share/perl6/sources/24DD121B5B4774C04A7084827BFAD92199756E03 (NativeCall) line 283
  in method CALL-ME at /Users/sno/rakudo/share/perl6/sources/24DD121B5B4774C04A7084827BFAD92199756E03 (NativeCall) line 570
  in sub MAIN at statgrab.p6 line 95
  in block <unit> at statgrab.p6 line 93

好的 - 给它一些搜索路径：

$ LD_LIBRARY_PATH=/opt/pkg/lib:$LD_LIBRARY_PATH perl6 statgrab.p6
Cannot locate native library 'libstatgrab.dylib': dlopen(libstatgrab.dylib, 1): image not found

使用DYLD_LIBRARY_PATH时的相同图片 - dlopen（3）也支持达尔文。

但是在目录中更改有效：

$ (cd /opt/pkg/lib && perl6 /data/Projects/OSS/p6-Unix-Statgrab/statgrab.p6 )
You're using Darwin on ernie.[...]

在调用moarvm的方式中是否缺乏搜索路径？

Answer 1

doug$ perl6 -v
This is Rakudo Star version 2018.10 built on MoarVM version 2018.10
implementing Perl 6.c.

在MacOS High Sierra上最近的Rakudo Star上，这个剧本对我来说是“开箱即用”的：

1. 编辑脚本删除'...'。
2. 脚本无法加载库（真的丢失！）
3. brew install libstatgrab
4. 脚本成功运行：

vader:learning doug$ perl6 nativecall_mac_Sno.pl6 
You're using Darwin on Vader.local

Homebrew安装库如下：

$ v /usr/local/lib
total 11904
-rw-r--r--  1 doug  admin  6080828 Sep 23 12:40 libmoar.dylib
lrwxr-xr-x  1 doug  admin       51 Mar 23 11:02 libstatgrab.10.dylib@ -> ../Cellar/libstatgrab/0.91/lib/libstatgrab.10.dylib
lrwxr-xr-x  1 doug  admin       44 Mar 23 11:02 libstatgrab.a@ -> ../Cellar/libstatgrab/0.91/lib/libstatgrab.a
lrwxr-xr-x  1 doug  admin       48 Mar 23 11:02 libstatgrab.dylib@ -> ../Cellar/libstatgrab/0.91/lib/libstatgrab.dylib
drwxr-xr-x  3 doug  admin      102 Mar 23 11:02 pkgconfig/

对我来说，perl6可执行文件确实是一个shell脚本，但它有效（没有必要传递任何额外的LD_LIBRARY_PATH=...）。

doug$ file `which perl6`
/Applications/Rakudo/bin/perl6: POSIX shell script text executable, ASCII text, with very long lines
doug$ set | grep LIBRARY
doug$

我的nativecall脚本也找到了库的问题，但总是通过修复库安装和/或提供'LD_LIBRARY_PATH'来解决它们。

对不起，这次经历对你来说不是很棒