在Modelica.Electrical.Quasistationary中绘制时间信号。

Question

我想建立一个平衡的三相星形连接模型（见图1）。图片1 我想得到这样的模拟结果(见图2)照片2：R1.V，R2.V，R3.V。. 下面是一些基本的方程 照片3.

我试了很多次都没有成功，谁能检查并修正我的模型，让我得到和foto 2一样的模拟结果？

model Unnamed
 parameter Integer m=3 "Number of phases";
     Modelica.Electrical.QuasiStationary.MultiPhase.Basic.Star starS annotation (
     Placement(transformation(
        extent={{-10,-10},{10,10}},
        rotation=180,
        origin={-22,70})));
  Modelica.Electrical.QuasiStationary.SinglePhase.Basic.Ground groundS
    annotation (Placement(transformation(
        extent={{-10,-10},{10,10}},
        rotation=0,
        origin={-56,18})));
 Modelica.Electrical.QuasiStationary.MultiPhase.Basic.Resistor resistor(R_ref=
        fill(1000, 3))
    annotation (Placement(transformation(extent={{42,60},{62,80}})));
  Modelica.Electrical.QuasiStationary.MultiPhase.Sources.VoltageSource
    voltageSource1(m=m,
    f=50,
    V=fill(230,m),
    phi=-Modelica.Electrical.MultiPhase.Functions.symmetricOrientation(3))
    "{(-(j - 1))*2*Modelica.Constants.pi/(m) for j in 1/m}"
    annotation (Placement(transformation(extent={{28,60},{8,80}})));
     Modelica.Electrical.QuasiStationary.MultiPhase.Basic.Star starS1
                                                                     annotation (
     Placement(transformation(
        extent={{-10,-10},{10,10}},
        rotation=0,
        origin={82,70})));
equation 
  connect(groundS.pin, starS.pin_n)
    annotation (Line(points={{-56,28},{-36,28},{-36,70},{-32,70}},
                                                 color={85,170,255}));
  connect(starS.plug_p, voltageSource1.plug_n)
    annotation (Line(points={{-12,70},{8,70}}, color={85,170,255}));
  connect(voltageSource1.plug_p, resistor.plug_p)
    annotation (Line(points={{28,70},{42,70}}, color={85,170,255}));
  connect(resistor.plug_n, starS1.plug_p)
    annotation (Line(points={{62,70},{72,70}}, color={85,170,255}));
  connect(starS1.pin_n, groundS.pin) annotation (Line(points={{92,70},{92,26},{-56,
          26},{-56,28}}, color={85,170,255}));
  annotation (uses(Modelica(version="3.2.2")));
end Unnamed;

谅谅

Answer 1

该 Modelica.Electrical.QuasiStationary 包是基于相位的，因此绘制正弦信号似乎有点困难--至少我没有找到直接的方法......。

因此。有什么特别的理由要使用QuasiStationary软件包吗？比较明显的方法是使用 Modelica.Electrical.MultiPhase 在我看来。例如，这可能会导致流动的代码，它从 Modelica.Electrical.MultiPhase.Examples.TransformerYY:

model ResistorThreephase "Test example with multiphase components"
  extends Modelica.Icons.Example;
  parameter Integer m=3 "Number of phases";
  parameter Modelica.SIunits.Voltage V=230 "Amplitude of Star-Voltage";
  parameter Modelica.SIunits.Frequency f=50 "Frequency";
  parameter Modelica.SIunits.Resistance RL=1e3 "Load Resistance";

  Modelica.Electrical.MultiPhase.Sources.SineVoltage sineVoltage(
    V=fill(V, m),
    freqHz=fill(f, m),
    m=m) annotation (Placement(transformation(
        origin={-30,20},
        extent={{-10,-10},{10,10}},
        rotation=180)));
  Modelica.Electrical.MultiPhase.Basic.Star starS(m=m)
    annotation (Placement(transformation(
        origin={-70,20},
        extent={{-10,-10},{10,10}},
        rotation=180)));
  Modelica.Electrical.Analog.Basic.Ground groundS annotation (Placement(
        transformation(extent={{-100,-40},{-80,-20}})));
  Modelica.Electrical.MultiPhase.Basic.Resistor loadR(m=m, R=fill(RL, m))
    annotation (Placement(transformation(extent={{20,10},{40,30}})));
  Modelica.Electrical.MultiPhase.Basic.Star starL(m=m)
    annotation (Placement(transformation(
        origin={70,20},
        extent={{-10,-10},{10,10}},
        rotation=0)));

equation 
  connect(starS.pin_n, groundS.p)
    annotation (Line(points={{-80,20},{-90,20},{-90,-20}}, color={0,0,255}));
  connect(starS.plug_p, sineVoltage.plug_n)
    annotation (Line(points={{-60,20},{-40,20}}, color={0,0,255}));
  connect(loadR.plug_n, starL.plug_p)
    annotation (Line(points={{40,20},{60,20}}, color={0,0,255}));
  connect(sineVoltage.plug_p, loadR.plug_p) annotation (Line(points={{-20,20},{20,20}}, color={0,0,255}));
  connect(starL.pin_n, groundS.p) annotation (Line(points={{80,20},{90,20},{90,-20},{-90,-20}}, color={0,0,255}));

  annotation (
    experiment(StopTime=0.03, __Dymola_Algorithm="Dassl"),
    uses(Modelica(version="3.2.3")));
end ResistorThreephase;

Answer 2

谢谢你的快速反应和编辑我的问题。

在你修改的模型中，我得到了我想要的模拟结果。

为什么要使用QuasiStationary包？ 我想建立一个包含过度确定的连接操作符" connections.branch() "的电气模型，以连接可能包含冗余变量(方向，参考角度)的连接器，这些变量具有相同的1个参考角度(reside)。

如同 Modelica.Electrical.QuasiStationary.MultiPhase.Basic.Star starS

更确切地说，是在Modelica.Electrical.QuasiStationary.MultiPhase.Basic.PlugToPin_p 如果我用 Modelica.Electrical.MultiPhase 我不会意识到