设置文件名是否可以从可执行文件版本号派生？

Question

是否可以让Inno Setup读取主可执行文件的文件版本，并将创建的设置的名称设置为“myapp_setup_1_0_3708_19805.exe”？

Answer 1

你应该能够这样做：

（我最近没有尝试过，但它肯定会在2007年以这种方式使用InnoSetup。如果Inno的语法从那时起发生了变化，可能需要稍微修改一下。）

#define MainBinaryName  "MyMainFile.exe"
#define SetupBaseName   "setup_mytool_"
#define AppVersion      GetFileVersion(AddBackslash(SourcePath) + MainBinaryName)
#define AVF1            Copy(AppVersion, 1, Pos(".", AppVersion) - 1) + "_" + Copy(AppVersion, Pos(".", AppVersion) + 1)
#define AVF2            Copy(AVF1,       1, Pos(".", AVF1      ) - 1) + "_" + Copy(AVF1      , Pos(".", AVF1      ) + 1)
#define AppVersionFile  Copy(AVF2,       1, Pos(".", AVF2      ) - 1) + "_" + Copy(AVF2      , Pos(".", AVF2      ) + 1)

[Setup]
OutputBaseFilename={#SetupBaseName + AppVersionFile}

如果MyMainFile.exe是版本1.2.3.4那么应调用已完成的安装程序setup_mytool_1_2_3_4.exe

AVF1，AVF2等东西只是用下划线（_）替换版本号中的点（。），以避免导致无法处理文件名中的大量点的问题。

Answer 2

; Get the App Version from Main Program
; This Is Full App Version Major.Minor.Build.Revision
; Store First 3 Parts of Version in ShortAppVersion to be used for SBS Assembly Installation Major.Minor.Build
#dim Version[4]
#expr ParseVersion("MainProgram.exe", Version[0], Version[1], Version[2], Version[3])
#define AppVersion Str(Version[0]) + "." + Str(Version[1]) + "." + Str(Version[2]) + "." + Str(Version[3])
#define ShortAppVersion Str(Version[0]) + "." + Str(Version[1]) + "." + Str(Version[2])

Answer 3

更简洁的方法是使用StringChange函数，它允许用其他东西替换点：

#define MainBinaryName  "MyMainFile.exe"
#define SourcePath      "Path/To/File"
#define SetupBaseName   "setup_mytool_"
#define AppVersion      GetFileVersion(AddBackslash(SourcePath) + MainBinaryName)
#define AppVersionFile  StringChange(AppVersion, ".", "_")

[Setup]
OutputBaseFilename={#SetupBaseName + AppVersionFile}

此外，如果您不想显示所有四个版本号（例如，您希望它显示1.0.1而不是1.0.1.0），您可以使用以下内容替换AppVersion行：

#define NumberOfVersionPoints  3
#define AppVersion             Copy(GetFileVersion(AddBackslash(SourcePath) + MainBinaryName), 0, NumberOfVersionPoints * 2 - 1)

Answer 4

GetFileVersion()（在其他答案中描述）返回“Major.Minor.Rev.Build”形式的字符串。如果您想要访问各个元素，以便您可以自己格式化字符串（例如，如果您只想要“Major.Minor”或“Major.Minor.Rev”），您可以使用jrsoftware.innosetup mailing list中的以下方法：

#define VerMajor
#define VerMinor
#define VerRev
#define VerBuild
#define FullVersion=ParseVersion('PathTo.exe', VerMajor, VerMinor, VerRev, VerBuild)
#define MyAppVersion = Str(VerMajor) + "." + Str(VerMinor)