如何使用 AutoHotkey 获取 Microsoft Teams 活动会议窗口？

Question

在 Microsoft Teams Windows 客户端中，我希望能够使用 AutoHotkey 识别当前活动的会议窗口。 考虑一下您可以打开多个 Teams 窗口（弹出的聊天窗口、主窗口、几个会议窗口，其中一些窗口处于保留状态，...）

（背景：我希望这样做是为了能够发送会议特定操作热键。）

Answer 1

我采用了另一种基于 FindText 的方法来排除任何用户提示。 它会检查 Teams 窗口中的“离开”和“恢复”等 UI 元素是否可用，以 100% 排除错误的窗口。

请参阅这篇文章的详细说明：https://tdalon.blogspot.com/2021/04/ahk-get-teams-meeting-window.html 与截屏视频。 这里是要点中的代码：https://gist.github.com/tdalon/d376a2ac395a41c5453904222cbcb529

摘录如下：

Teams_GetMeetingWindow(useFindText:="" , restore := True){
; See implementation explanations here: 
;   https://tdalon.blogspot.com/2021/04/ahk-get-teams-meeting-window.html
;   https://tdalon.blogspot.com/2020/10/get-teams-window-ahk.html

If (useFindText="")
    useFindText := PowerTools_GetParam("TeamsMeetingWinUseFindText") ; Default 1

If (useFindText) {
    If (restore)
        WinGet, curWinId, ID, A
    ResumeText:="|<>*138$51.zzzzzzzzw3zzzzzzzUDzzzzzzwtzzzzzzzbA64NU1kQ1423A04FUtUQNa8aAX0EXAlY1a9zUNaAbwt4Y0AlYHb4461aAkTzzzzzzzzU" ; FindText for Resume
    LeaveText:="|<>*168$66.zzzzzzzzzzzzzzzzDzzzzzy01zzDzzzzzs00TzDzzzzzk00DzDkkFW3U7k7zDUG9YFUDk7zD6T9YlUTs7zD0E841kTs7zD7nAAzszwDz022AAHzzzzz0UECS3zzzzzzzzzzzU"
}

WinGet, Win, List, ahk_exe Teams.exe
TeamsMainWinId := Teams_GetMainWindow()
TeamsMeetingWinId := PowerTools_RegRead("TeamsMeetingWinId")
WinCount := 0
Select := 0


Loop %Win% {
    WinId := Win%A_Index%
    If (WinId = TeamsMainWinId) { ; Exclude Main Teams Window 
        ;WinGetTitle, Title, % "ahk_id " WinId
        ;MsgBox %Title%
        Continue
    }
    WinGetTitle, Title, % "ahk_id " WinId  
    
    IfEqual, Title,, Continue
    Title := StrReplace(Title," | Microsoft Teams","")
    If RegExMatch(Title,"^[^\s]*\s?[^\s]*,[^\s]*\s?[^\s]*$") or RegExMatch(Title,"^[^\s]*\s?[^\s]*,[^\s]*\s?[^\s]*\([^\s\(\)]*\)$") ; Exclude windows with , in the title (Popped-out 1-1 chat) and max two words before , Name, Firstname               
        Continue
    
    If RegExMatch(Title,"^Microsoft Teams Call in progress*") or RegExMatch(Title,"^Microsoft Teams Notification*") or RegExMatch(Title,"^Screen sharing toolbar*")
        Continue
    
    If (useFindText) {
        ; Exclude window with no Leave element
        WinActivate, ahk_id %WinId%
        If !(ok:=FindText(,,,, 0, 0, LeaveText,,0)) {
            Continue
        } 
        
        ; Final check - exclude window with Resume element = On hold meetings
        If (ok:=FindText(,,,, 0, 0, ResumeText,,0)) {
            Continue
        } 
    }
        
    WinList .= ( (WinList<>"") ? "|" : "" ) Title "  {" WinId "}"
    WinCount++

    ; Select by default last meeting window used
    If WinId = %TeamsMeetingWinId% 
        Select := WinCount  
} ; End Loop

If (WinCount = 0)
    return
If (WinCount = 1) { ; only one other window
    RegExMatch(WinList,"\{([^}]*)\}$",WinId)
    TeamsMeetingWinId := WinId1
    PowerTools_RegWrite("TeamsMeetingWinId",TeamsMeetingWinId)
    return TeamsMeetingWinId
}

If (restore)
    WinActivate, ahk_id %curWinId%

LB := WinListBox("Teams: Meeting Window", "Select your current Teams Meeting Window:" , WinList, Select)
RegExMatch(LB,"\{([^}]*)\}$",WinId)
TeamsMeetingWinId := WinId1
PowerTools_RegWrite("TeamsMeetingWinId",TeamsMeetingWinId)
return TeamsMeetingWinId

} ; eofun

Answer 2

我尝试通过窗口标题找到它，但 Teams 没有以特定方式命名会议窗口。

我可以通过 AccViewer 发现主团队窗口的名称以“| Microsoft Teams，主窗口”结尾。所以至少我可以排除这个。

Here是我遇到的一个旧解决方案。 但它要求用户确认哪个窗口是当前会议窗口（如果不明显的话）。

代码可以在此要点中找到：https://gist.github.com/tdalon/87590637e43479c90f355be90aff3842#file-teams_getmeetingwindow-ahk

Answer 3

这是我当前基于 UIAutomation 库的实现 - 请参阅 https://tdalon.blogspot.com/2022/07/ahk-get-teams-meeting-win.html

要点代码https://gist.github.com/tdalon/5b3304559852d1d1942b7f1566de2a0c