在 ADO (ODBC) 中使用日期时间参数会丢失时间部分

Question

昨天我在忙于使用 SQLLite 编写一些单元测试时偶然发现了这个问题。我的环境是Windows7/Delphi XE。

将 TADOQuery 与 TDateTime 参数结合使用会导致时间部分丢失。

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ADODb, DateUtils, DB;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);

var DbConn : TADOConnection;
    Qry    : TADOQuery;
    DT     : TDateTime;

begin
 DBConn := TADOConnection.Create(nil);
 DBConn.ConnectionString := 'Provider=MSDASQL.1;Extended Properties="DRIVER=SQLite3 ODBC Driver;Database=:memory:;LongNames=0;Timeout=1000;NoTXN=0;SyncPragma=NORMAL;StepAPI=0;"';
//   DBConn.ConnectionString := 'Provider=MSDASQL.1;Persist Security Info=True;User ID=%0:s;Password=%1:s;Extended Properties="DRIVER={MySQL ODBC 5.1 Driver};SERVER=localhost;PORT=3306;DATABASE=test;USER=root;PASSWORD=rrr;OPTION=1048579"';
 Qry := TADOQuery.Create(nil);
 Qry.Connection := DbConn;
 try
  DBConn.Connected := True;
  Qry.SQL.Text := 'CREATE TABLE test(d datetime)';
  Qry.ExecSQL;
  Qry.ParamCheck := True;
  Qry.SQL.Text := 'INSERT INTO test (d) VALUES (:d)';
  //Qry.Parameters.ParseSQL(Qry.SQL.Text, True); // not needed
  TryEncodeDateTime(1999, 12, 12, 10, 59, 12, 0, DT);
  Qry.Parameters.ParamByName('d').Value := DT;
  Qry.Parameters.ParamByName('d').DataType := ftDateTime;
  Qry.ExecSQL;
  Qry.SQL.Text := 'SELECT d FROM test';
  Qry.Open;
  ShowMessage(FormatDateTime('MM/DD/YYYY HH:NN:SS', Qry.FieldByName('d').AsDateTime));
 finally
  FreeAndNil(Qry);
  FreeAndNil(DbConn);
 end;
end;

有趣的是，当我评论该行时

Qry.Parameters.ParseSQL(Qry.SQL.Text, True);

它会正常工作。我需要 ParseSQL 部分，因为我正在构建一个迷你 ORM，因此它需要知道必须映射哪些参数。 一些观察：

• 使用 MySQL5 进行相同的测试显示相同的问题（无论 ParseSQL 部分如何）。
• 此代码适用于 SQL Server 和 OLEDB 驱动程序。

我在网上搜索并发现了一些有趣的链接：

http://tracker.firebirdsql.org/browse/ODBC-27

http://embarcadero.newsgroups.archived.at/public.delphi.database.ado/201107/1107112007.html

http://bugs.mysql.com/bug.php?id=15681

第一个链接建议“修复”ADODB.pas，这是我不想做的事情。 阅读最后一个链接，似乎 ADO 将日期时间值映射到日期。

我不想听到的答案：使用另一个库/组件（如 Dbexpress、Zeoslib，...）

我不确定解决这个问题最明智的方法是什么。

正如 Linas 和 Marjan Venema 建议的那样，我可以省略 ParseSQL 部分。 因此，如果我省略了行

Qry.Parameters.ParamByName('d').DataType := ftDateTime;

，代码现在可以在 SQLlite 上运行。

但是MySQL拒绝保存时间部分。 我在这里看到 ADO 和 MySQL ODBC 之间的兼容性问题吗？

Answer 1

我已经使用 SQL Server 对此进行了一些测试，并且在使用 MSDASQL.1 (ODBC) 时遇到了完全相同的问题。您的代码可以在 SQLOLEDB.1 和 SQLNCLI10.1 上正常工作。

如果将参数类型指定为

ftString

，使用 ODBC 会节省时间（至少在 SQL Server 上）。

Qry.Parameters.ParamByName('d').DataType := ftString;
Qry.Parameters.ParamByName('d').Value := DateTimeToStr(DT);

注意：使用 DateTimeToStr 时请注意本地设置，它可能不会产生数据库想要的结果。一个安全的选择是使用

yyyy-mm-dd hh:mm:ss[.fff]

。

更新：

您也可以自行将ado参数的数据类型设置为

adDBTimeStamp

。当您使用

adDate

时，ADODB 将其设置为

ftDateTime

。

Qry.Parameters.ParamByName('d').ParameterObject.Type_ := adDBTimeStamp;
Qry.Parameters.ParamByName('d').Value := DT;

Answer 2

我在使用 Delphi 11.3 从 SQL Server 2019 导入数据以保存另一个数据库时遇到了同样的困难。

我解决了这样的情况：

准备SQL：

ADOCommand.CommandText := 'insert into TABLE (CREATED_AT) VALUES (:CREATED_AT)';

循环（ADOTableSource）：

var FieldSource := ADOTableSource.FieldByName(FieldName);
var ParamTarget := ADOCommand.Parameters.ParamByName(FieldName);
if (FieldSource.DataType in [ftDateTime]) and (not FieldSource.IsNull) then
begin
  ParamTarget.DataType := ftString;
  ParamTarget.Value := FormatDateTime('yyyy-mm-dd hh:nn:ss.zzz', FieldSource.AsDateTime);
end
else 
  ParamTarget.Value := FieldSource.Value;
  
ADOCommand.Execute;

现在日期已正确保存为

2023-02-28 23:59:09.123

，不再是

2023-02-28 23:59:09.000

。

Answer 3

我在使用 VFPOLEDB（Visual FoxPro 驱动程序）时遇到了同样的问题，但

adDBTimeStamp

的技巧不起作用。 FWIW，这是带有 Delphi 7 和 RAD Studio 10（西雅图）的 VFPOLEDB 9.0.0.5815。

对于 VFPOLEDB，还有另一种可能的解决方法，该解决方法基于以下事实：在 Fox 中，日期/时间值（类型“T”）的基础表示与传递的日期值（类型“D”）的底层表示相同由 OLEDB 表示，即 64 位双精度数，其中整数部分表示自 0001 年 1 月 1 日以来的天数，小数部分表示一天中的时间。

如果表字段的类型为“T”并且 OLEDB 传递日期，则 Fox 会通过不执行任何操作来强制该值。所以这里所需要的只是添加回小数部分。

示例，

start_time

是日期/时间字段：

cmd.CommandText := 'insert into foo (start_time) values (:start_time)';
cmd.Parameters.ParamByName('start_time') := Now;
cmd.Execute;

这在表中给出了

2016-05-22 00:00:00

。

现在，添加小数部分，如下所示：

cmd.CommandText := 'insert into foo (start_time) values (:start_time + :fraction)';
t := Now;
cmd.Parameters.ParamByName('start_time') := t;
cmd.Parameters.ParamByName('fraction') := Frac(t);
cmd.Execute;

这给出了

2016-05-22 02:17:42

。即使小数秒也会被保留，尽管它们不会被显示。