在表中的特定列上使用substitute（）来更改日期

Question

我正在尝试在表中的特定列上使用substitute（）。所有日期均输入13.03.2019。我需要更换“。”使用“/”可以在其他公式中使用它们。

我怎么能让这个公式改变整个栏目？我设法做了一个单细胞。

这适用于表外的单个单元格。但我需要更改表格中整列的日期。

    wsDormant.Range("C8") = WorksheetFunction.Substitute(wsDormant.Range("C8"), ".", "/")

这是表格列：

With wsDormant.ListObjects("Table_Dormant_Stock")
        .Range.AutoFilter

        'Convert date format
        .ListColumns("Days Last Sold").DataBodyRange.Formula = WorksheetFunction.Substitute(.ListColumns("Days Last Sold").DataBodyRange, ".", "/")

End With

它应该从15.03.2019变为15/03/2019

Answer 1

您不能在对一系列单元格的赋值中使用替换或替换，并且不能将公式应用于引用自身的整个列（如在您的尝试中）。

如果它只是一个小表，您可以通过ListColumn在惰性循环中使用单细胞解决方案：

Dim raCell as Range

For each raCell in wsDormant.ListObjects("Table_Dormant_Stock").ListColumns("Days Last Sold").DataBodyRange
    raCell = WorksheetFunction.Substitute(raCell, ".", "/")
Next

或者，正如Scott指出的那样，使用本机VBA函数Replace更有效：

Dim raCell as Range

For each raCell in wsDormant.ListObjects("Table_Dormant_Stock").ListColumns("Days Last Sold").DataBodyRange
    raCell = Replace(raCell, ".", "/")
Next

也就是说，如果您正在处理大型列表，这两种解决方案仍然效率低下。

更有效的解决方案是使用SUBSTITUTE函数创建临时工作列：

With wsDormant.ListObjects("Table_Dormant_Stock").ListColumns.Add
    .DataBodyRange.Formula = "=SUBSTITUTE([@[Days Last Sold]], ""."", ""/"")"
    wsDormant.ListObjects("Table_Dormant_Stock").ListColumns("Days Last Sold").DataBodyRange.Value = .DataBodyRange.Value
    .Delete
End With

另一种有效的解决方案是将所有值复制到数组，循环遍历该数组，然后将更新的值复制回电子表格：

Dim varArray As Variant, i As Integer

With wsDormant.ListObjects("Table_Dormant_Stock").ListColumns("Days Last Sold")
    varArray = .DataBodyRange
    For i = 1 To UBound(varArray, 1)
        varArray(i, 1) = Replace(varArray(i, 1), ".", "/")
    Next i
    .DataBodyRange = varArray
End With