如何根据值确定节点的位置

问题描述 投票：0回答：1

我正在尝试根据节点的值获取节点的位置，以便我可以获取相应的条目。

这是源 XML：

<?xml version="1.0" encoding="UTF-8"?>
<sampleSourceXML>
    <Table>
        <Header>
            <Column>Name</Column>
            <Column>Surname</Column>
            <Column>Title</Column>
        </Header>
        <Body>
            <Row>
                <Entry>James</Entry>
                <Entry>Bond</Entry>
                <Entry>Mr</Entry>
            </Row>
            <Row>
                <Entry>Harry</Entry>
                <Entry>Potter</Entry>
                <Entry>Mr</Entry>
            </Row>
        </Body>
    </Table>
</sampleSourceXML>

这是我想要实现的 XML 结果：

<?xml version="1.0" encoding="UTF-8"?>
<sampleResultXML>
    <Person>
        <FirstName>James</FirstName>
        <LastName>Bond</LastName>
        <Title>Mr</Title>
    </Person>
    <Person>
        <FirstName>Harry</FirstName>
        <LastName>Potter</LastName>
        <Title>Mr</Title>
    </Person>
</sampleResultXML>

我用这个 XSLT 尝试过：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>
    
    <xsl:template match="/">
        <xsl:element name="sampleResultXML">
            <xsl:for-each select="sampleSourceXML/Table/Rows/Row">
                <xsl:element name="Person">
                    <xsl:element name="FirstName">
                        <xsl:value-of select="./Entry[1]/text()"></xsl:value-of>
                    </xsl:element>
                    <xsl:element name="LastName">
                        <xsl:value-of select="./Entry[2]/text()"></xsl:value-of>
                    </xsl:element>
                    <xsl:element name="Title">
                        <xsl:value-of select="./Entry[3]/text()"></xsl:value-of>
                    </xsl:element>
                </xsl:element>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

这有效。

但是源 XML 可以有不同的顺序。例如，标题元素可以位于名称元素上方。因此，我的 XSLT 中的硬编码位置（例如 Entry[3]）将不再起作用。

标题顺序和条目顺序始终对应。因此，如果列标题位于位置 3，相应的行也将位于位置 3。

所以我需要一种方法来动态获取 Title 元素的位置。因此，我必须遍历 Column 元素，直到到达值为“Title”的元素。我想将这个位置保存在变量中（例如 Position_Title），以便稍后可以像这样填充该值：

<xsl:element name="Title">
  <xsl:value-of select="./Entry[$Position_Title]/text()"></xsl:value-of>
</xsl:element>

但是我还没有找到方法来做到这一点。

您对我如何实现这一目标有什么想法吗？

xslt-1.0
1个回答
2
投票

所以我需要一种方法来动态获取 Title 元素的位置。因此，我必须遍历 Column 元素，直到到达值为“Title”的元素。我想将这个位置保存在变量中（例如 Position_Title），以便稍后可以像这样填充该值：

我认为如果你从相反的方向做的话可能会简单得多。尝试：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/sampleSourceXML">
    <xsl:variable name="cols" select="Table/Header/Column" />
    <sampleResultXML>
        <xsl:for-each select="Table/Body/Row">
            <Person>
                <xsl:for-each select="Entry">
                    <xsl:variable name="i" select="position()" />
                    <xsl:element name="{$cols[$i]}">
                        <xsl:value-of select="."/>
                    </xsl:element>
                </xsl:for-each> 
            </Person>
        </xsl:for-each> 
    </sampleResultXML>
</xsl:template>

</xsl:stylesheet>
最新问题
© www.soinside.com 2019 - 2024. All rights reserved.