如何在Fortran90中向动态数组添加新元素

Question

[由francescalus解决]。双精度动态数组的工作代码为：

  module DynamicalArrays

  contains

      subroutine AddToList(list, element)

          IMPLICIT NONE

          integer :: i, isize
          double precision, intent(in) :: element
          double precision, dimension(:), allocatable, intent(inout) :: list
          double precision, dimension(:), allocatable :: clist


          if(allocated(list)) then
              isize = size(list)
              allocate(clist(isize+1))
              do i=1,isize          
              clist(i) = list(i)
              end do
              clist(isize+1) = element

              deallocate(list)
              call move_alloc(clist, list)

          else
              allocate(list(1))
              list(1) = element
          end if


      end subroutine AddToList


  end module DynamicalArrays

演示子例程，可以从中填充数组：

  subroutine UserDArrayTest()

  use DynamicalArrays


  integer :: i
  double precision, dimension(:), allocatable :: list
  double precision :: temp

  temp = 0.1
  do i=1,10
    temp = temp+1
    call AddToList(list, temp)
  end do

  do i=1,10
    print *, i, list(i)
  end do


  end

注意，最好将模块代码保存在单独的文件中，但是我还发现，当模块代码位于主程序和子例程代码之上时，它可以工作。

---------------原始问题-----------------

我最初无法预测数组的确切大小时，需要在Fortran 90中使用动态数组。因此，我编写了代码，每次将新元素添加到数组末尾时，该代码均应扩展可分配数组：

  subroutine DArray()

  double precision, dimension(:), allocatable :: list

  allocate(list(1))

  list(1) = 1.1

  call AddToList(list, 2.2)
  call AddToList(list, 3.2)
  call AddToList(list, 4.2)
  call AddToList(list, 5.2)

  print *, list(1)
  print *, list(2)
  print *, list(3)
  print *, list(4)
  print *, list(5)


  end



  subroutine AddToList(list, element)

  double precision :: element
  double precision, dimension(:), allocatable :: list
  double precision, dimension(:), allocatable :: clist

  if(allocated(list)) then
    isize = size(list)
    allocate(clist(isize+1))
    do i=1,isize
        clist(i) = list(i)
    end do
    clist(i+1) = element

    deallocate(list)
    allocate(list(isize+1))

    do i=1,isize+1
        list(i) = clist(i)
    end do

    deallocate(clist)

  end if


  end

所以有人看到我在这里缺少什么吗？[已解决-请在下方查看答案和完整代码]

Answer 1

[我怀疑，看着一件文物，您注意到了问题-但很快就继续前进。

对我来说可疑的电话是：

    allocate(clist(isize+2))

为什么不是新尺寸isize+1？我猜您尝试过，但是程序失败了。

查看程序为何失败（可能崩溃）是为什么您未获得正确结果的关键。仔细查看循环（为清楚起见，删除了打印语句）。

do i=1,isize
    clist(i) = list(i)
end do
clist(i+1) = element

您想说“将所有元素从列表复制到clist，然后追加元素”。哪个是对的。但是

do i=1,isize
    clist(i) = list(i)
end do
! Here, i=isize+1
clist(i+1) = element
! Which means
! clist(isize+2) = element.

总而言之，在循环之后，循环索引变量没有其在最终迭代中具有的值。

Answer 2

我知道这个问题很老，但是最近我不得不构建这样的子例程，我发现从Fortran2003开始，有一个漂亮的衬里：

    SUBROUTINE append_int(vec, val)
    !***********************************************************************
    !> \brief Appends val in vec if not already present
    !> \date 05 2020
    !***********************************************************************
    INTEGER, DIMENSION(:), ALLOCATABLE, INTENT(INOUT)    :: vec
    INTEGER, INTENT(IN)                                  :: val

    ! Remove this test if you don't mind not having unique values
    IF (.NOT. ANY(vec .EQ. val)) THEN
        vec = [vec, val]
    END IF

    END SUBROUTINE

您的数组将自动以适当的大小重新分配。另外，您可以为Reals生成等效的例程，以将一个数组追加到另一个...，然后将它们全部包装在接口中，以便无论数据类型如何，您始终可以调用同一子例程。