SPSS 中的双重差分分析

Question

我试图比较 1993 年 EITC 制度改革前后“单亲妈妈与一个孩子”和“单亲妈妈与一个以上孩子”这两个群体的情况。

通过SPSS中的T检验程序，我可以得到改革前后各组之间的差异。但是我如何获得差异中的差异（我仍然想要标准错误）？

我找到了 STATA 和 R 的这些方法（http://thetarzan.wordpress.com/2011/06/20/differences-in-differences-estimation-in-r-and-stata/），但我可以' SPSS 中似乎没有弄清楚。

希望有人能够提供帮助。

祝一切顺利， 安妮

Answer 1

这可以通过 GENLIN 程序来完成。这是我生成的一些随机数据，用于展示如何操作：

data list list /after oneChild value.
begin data.
0   1   12
0   1   12
0   1   11
0   1   13
0   1   11
1   1   10
1   1   9
1   1   8
1   1   9
1   1   7
0   0   16
0   0   16
0   0   18
0   0   15
0   0   17
1   0   6
1   0   6
1   0   5
1   0   5
1   0   4
end data.
dataset name exampleData WINDOW=front.
EXECUTE.

value labels after 0 'before' 1 'after'.
value labels oneChild 0 '>1 child' 1 '1 child'.

各组的平均值（按顺序，在我截断为整数之前）分别为 17、6、12 和 9。因此，我们的 GENLIN 过程应该生成值 -11（>1 个子组中的前后差异）、-5（1 个子组 - >1 个子组的差异）和 8（前后差异的子组差异） ).

将数据绘制成图表，这样您就可以看到我们的期望：

* Chart Builder.
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=after value oneChild MISSING=LISTWISE REPORTMISSING=NO    
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
  SOURCE: s=userSource(id("graphdataset"))
  DATA: after=col(source(s), name("after"), unit.category())
  DATA: value=col(source(s), name("value"))
  DATA: oneChild=col(source(s), name("oneChild"), unit.category())
  GUIDE: axis(dim(2), label("value"))
  GUIDE: legend(aesthetic(aesthetic.color.interior), label(""))
  SCALE: linear(dim(2), include(0))
  ELEMENT: line(position(smooth.linear(after*value)), color.interior(oneChild))
  ELEMENT: point.dodge.symmetric(position(after*value), color.interior(oneChild))
END GPL.

现在，对于 GENLIN：

* Generalized Linear Models.
GENLIN value BY after oneChild (ORDER=DESCENDING)
  /MODEL after oneChild after*oneChild INTERCEPT=YES
 DISTRIBUTION=NORMAL LINK=IDENTITY
  /CRITERIA SCALE=MLE COVB=MODEL PCONVERGE=1E-006(ABSOLUTE) SINGULAR=1E-012 ANALYSISTYPE=3(WALD) 
    CILEVEL=95 CITYPE=WALD LIKELIHOOD=FULL
  /MISSING CLASSMISSING=EXCLUDE
  /PRINT CPS DESCRIPTIVES MODELINFO FIT SUMMARY SOLUTION.

结果表显示了我们的预期。

• >1 名儿童组之后与之前相比降低了 12.3 - 10.1。这个 95% CI 包含 11 的“真实”值

• >1个孩子和1个孩子之前的差值是5.7 - 3.5，包含真实值5

• 差中之差为 9.6 - 6.4，包含 (17-6) - (12-9) = 8 的实际值

标准。误差、p 值和其他假设检验值也会被报告。希望有帮助。

编辑：这可以通过自己计算交互项并进行简单的线性回归，以不太“复杂”的语法来完成：

compute interaction = after*onechild.
execute.

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT value
  /METHOD=ENTER after oneChild interaction.

请注意，得到的标准误差和置信区间实际上与之前的方法不同。我对 SPSS 的 GENLIN 和 REGRESSION 程序了解不够，无法告诉你为什么会出现这种情况。在这个人为的示例中，您从数据中得出的结论将大致相同。在现实生活中，数据不太可能这么干净，所以我不知道哪种方法“更好”。

Answer 2

一般线性模型，我将其视为“方差分析”模型。

因此请使用SPSS的Analyze菜单中的相关模块。

T检验后，需要检查各组的sigma相等性。

Answer 3

关于上面第一个答案：

* Note that GENLIN uses maximum likelihood estimation (MLE) whereas REGRESSION
* uses ordinary least squares (OLS).  Therefore, GENLIN reports z- and Chi-square tests
* where REGRESSION reports t- and F-tests.  Rather than using GENLIN, use UNIANOVA
* to get the same results as REGRESSION, but without the need to compute your own
* product term.

UNIANOVA value BY after oneChild
  /PLOT=PROFILE(after*oneChild) 
  /PLOT=PROFILE(oneChild*after) 
  /PRINT PARAMETER
  /EMMEANS=TABLES(after*oneChild) COMPARE(after)
  /EMMEANS=TABLES(after*oneChild) COMPARE(oneChild)
  /DESIGN=after oneChild after*oneChild.

HTH.