Pretty Print Excel 公式？

Question

有没有办法漂亮地打印 Excel 公式？

我有一些半复杂公式的工作表需要努力完成，所以这会让我的生活更轻松一些。

我只是想转这样的东西

AC6+AD6+(IF(H6="Yes",1,IF(J6="Yes",1,0)))+IF(X6="Yes",1,0)

无需在 Vim 或类似工具中手动操作，即可读成更具可读性的内容。 Excel 确实对括号进行了颜色匹配，但它们仍然全部混合在一行上。

Answer 1

试用 Excel 公式美化器 http://excelformulabeautifier.com/。它漂亮地打印（又名美化）Excel 公式。

（我帮助维护这个，一直在寻找反馈以使其变得更好。）

Answer 2

这段VBA代码不会得奖，但没关系。用于快速查看典型公式。它只是执行您手动使用括号或分隔符执行的操作。将其粘贴到代码模块中并从 VBA 即时窗口命令行调用它。 （编辑：我最近不得不看一些公式，我改进了我原来的答案，所以我回来改变了它。）

Public Function ppf(f) As String
    Dim formulaStr As String

    If IsObject(f) Then
        Debug.Assert TypeOf f Is Range

        Dim rng As Range
        Set rng = f

        formulaStr = rng.Formula
    Else
        Debug.Assert VarType(f) = vbString

        formulaStr = f
    End If

    Dim tabs(0 To 99) As Long

    Dim tabNum As Long
    tabNum = 1

    Dim tabOffset As Long

    Dim i As Long
    Dim c As String
    For i = 1 To Len(formulaStr)
        c = Mid$(formulaStr, i, 1)

        If InStr("({", c) > 0 Then
            ppf = ppf & c

            tabNum = tabNum + 1
            tabs(tabNum) = tabs(tabNum - 1) + tabOffset + 1
            tabOffset = 0

            ppf = ppf & vbCrLf & Space(tabs(tabNum))
        ElseIf InStr(")}", c) > 0 Then
            tabNum = tabNum - 1
            tabOffset = 0

            ppf = ppf & c & vbCrLf & Space(tabs(tabNum))
        ElseIf InStr("+-*/^,;", c) > 0 Then
            tabOffset = 0

            ppf = ppf & c & vbCrLf & Space(tabs(tabNum))
        Else
            ppf = ppf & c

            tabOffset = tabOffset + 1
        End If
    Next i
End Function

如果你这样称呼它：

?ppf([q42])

你不必担心转义你的双引号等等。你会得到如下所示的输出：

AC6+
AD6+
(
 IF(
    H6="Yes",
    1,
    IF(
       J6="Yes",
       1,
       0)
    )
 )
+
IF(
   X6="Yes",
   1,
   0)

你也可以用普通的字符串来调用它。

Answer 3

上面代码片段的这个版本现在也以不同的方式处理引用字符，这意味着，如果它们在字符串中，它不会影响缩进：

"This ({)},;+*-/ won't lead to a linebreak" 

它由布尔变量 bInsideQuotes 控制。 它还使用

.FormulaLocal

使最终用户能够看到他们知道的东西。

Public Function prettyPrintFormula(f As Variant) As String
    Dim formulaStr As String
    Dim ppf As String

    If IsObject(f) Then
        Debug.Assert TypeOf f Is Range

        Dim rng As Range
        Set rng = f

        formulaStr = rng.FormulaLocal
    Else
        Debug.Assert VarType(f) = vbString

        formulaStr = f
    End If

    Dim tabs(0 To 99) As Long

    Dim tabNum As Long
    tabNum = 1

    Dim tabOffset As Long

    Dim i As Long
    Dim c As String
    Dim bInsideQuotes As Boolean
    bInsideQuotes = False
    For i = 1 To Len(formulaStr)
        c = Mid$(formulaStr, i, 1)

        If InStr("""", c) > 0 Then
            bInsideQuotes = Not bInsideQuotes
        End If
        If InStr("({", c) > 0 And Not bInsideQuotes Then
            ppf = ppf & c

            tabNum = tabNum + 1
            tabs(tabNum) = tabs(tabNum - 1) + tabOffset + 1
            tabOffset = 0

            ppf = ppf & vbCrLf & Space(tabs(tabNum))
        ElseIf InStr(")}", c) > 0 And Not bInsideQuotes Then
            tabNum = tabNum - 1
            tabOffset = 0

            ppf = ppf & c & vbCrLf & Space(tabs(tabNum))
        ElseIf InStr("+-*/^,;", c) > 0 And Not bInsideQuotes Then
            tabOffset = 0

            ppf = ppf & c & vbCrLf & Space(tabs(tabNum))
        Else
            ppf = ppf & c

            tabOffset = tabOffset + 1
        End If
    Next i
    prettyPrintFormula = ppf
End Function

Answer 4

我刚刚使用 VS Code sql-formatter 扩展解决了这个问题。我只是将公式粘贴到 sql 文件并使用 sql-formatter 进行格式化。

当我把它归档

{=IFERROR(INDEX(names,SMALL(IF(groups=$E5,ROW(names)-MIN(ROW(names))+1),COLUMNS($E$5:E5))),"")}

结果是这样的：

{ = IFERROR(
  INDEX(
    NAMES,
    SMALL(
      IF(groups = $ E5, ROW(NAMES) - MIN(ROW(NAMES)) + 1),
      COLUMNS($ E $ 5 :E5)
    )
  ),
  ""
) }

不完美，但符合我的口味。这可以被复制并用回 Excel / 谷歌表格中。

Answer 5

2023 年，到目前为止，最简单的方法是安装微软自己的 Advanced Formula Environment。除了漂亮的打印公式（然后可以将其复制粘贴到常规公式栏中）之外，它还有许多其他功能。转到“插入”选项卡，“获取加载项”，搜索“Excel Labs”。

我也会衷心推荐“Formula Forge”插件作为 Evaluate Formula 的替代品。它使困难的公式更容易评估。