每个自定义抽动标签有不同的颜色

Question

如何设置不同颜色的自定义抽动标签？现在，我收到错误：未定义的变量：tc

set ytics ("1" 1.0 tc rgb 'purple', "0.8" 0.8 tc rgb 'purple', "1" 1.4 tc rgb 'forest-green', "0.8" 1.2 tc rgb 'forest-green', "1" 1.8 tc rgb 'black', "0.8" 1.6 tc rgb 'black')

set y2tics ("1" 1.2 tc rgb 'blue', "0.8" 1.0 tc rgb 'blue', "1" 1.6 tc rgb 'red', "0.8" 1.4 tc rgb 'red', "1" 2.0 tc rgb 'brown', "0.8" 1.8 tc rgb 'brown')

Answer 1

据我所知，您可以设置每个轴的抽动颜色（检查

help xtics

），但不能单独设置。所以你必须半手动地完成。一种方法是例如通过绘制箭头。也许根据整体情况/上下文，可能还有其他解决方案。

脚本：

### set custom & colored tics
reset session

$TicsY <<EOD
0.8   0.8   purple
1     1.0   purple
0.8   1.2   forest-green
1     1.4   forest-green
0.8   1.6   black
1     1.8   black
EOD

$TicsY2 <<EOD
0.8   1.0   blue
1     1.2   blue
0.8   1.4   red
1     1.6   red
0.8   1.8   brown
1     2.0   brown
EOD

set link y2 via y inverse y
set ytics nomirror
set y2tics nomirror

set for [i=1:|$TicsY|] arrow i from graph 0.02, first y0=word($TicsY[i],2) to graph 0, first y0 nohead lw 2 lc rgb word($TicsY[i],3)
set for [i=1:|$TicsY|] ytics (word($TicsY[i],1) word($TicsY[i],2))

set for [i=1:|$TicsY2|] arrow i+|$TicsY| from graph 0.98, second y0=word($TicsY2[i],2) to graph 1, second y0 nohead lw 2 lc rgb word($TicsY2[i],3)
set for [i=1:|$TicsY2|] y2tics (word($TicsY2[i],1) word($TicsY2[i],2))

plot [0.5:2.5] x
### end of script

结果：