我有一个交叉表查询,列中的字段的'mmm-yyyy'格式化日期。
我使用下面的Design来创建查询。
我遇到的问题是日期没有按照从12月17日到7月16日的降序顺序排序。这将是一个动态查询,每个月都会有几个月的变化,因此我想使用额外的数据表来进行排序(而不是在“属性”窗口中输入月份名称列表)。
我该如何修复我的查询才能让它做到这一点?
谢谢你的帮助
不幸的是,无论连接表如何排序,交叉表将默认按字母顺序对列进行排序,因此4月,12月,...开始订单。要更改甚至过滤交叉表中的列顺序,您可以在SQL语句的PIVOT Col IN ()
子句中指定值。
由于您需要动态查询,请考虑在VBA中创建querydef以更新交叉表后面的SQL,您可以在其中动态更新PIVOT Col IN ()
子句。当然,根据需要或通过参数传递开始和结束日期:
Public Sub BuildCrossTab()
Dim db As Database
Dim qdef As QueryDef
Dim strSQL As String, dates As String
Dim i As Integer, monthsDiff As Integer
Set db = CurrentDb
' DELETE PREVIOUS SAVED QUERY
For Each qdef in db.QueryDefs
If qdef.Name = "AccuralsCrosstabQ" Then
db.Execute "DROP Table " & qdef.Name, dbFailOnError
End If
Next qdef
' LOOP THROUGH ALL MONTHS BACKWARDS
dates = "("
monthsDiff = DateDiff("m", #7/1/2016#, #12/1/2016#)
For i = monthsDiff To 0 Step -1
dates = dates & " '" & Format(DateAdd("m", i, #7/1/2016#), "mmm-yyyy") & "',"
Next i
dates = dates & ")"
dates = Replace(dates, ",)", ")")
' PREPARE SQL STRING
strSQL = "TRANSFORM SUM(a.[Amount $]) AS SumAmount" _
& " SELECT a.Company, a.[Accrual ID], SUM(a.[Amount $]) As [Total Amount $]" _
& " FROM [Accruals Raw Data] a " _
& " GROUP BY a.Company, a.[Accrual ID]" _
& " PIVOT Format(a.[Posted Date], ""mmm-yyyy"")" _
& " IN " & dates
' CREATE QUERY
Set qdef = db.CreateQueryDef("AccuralsCrosstabQ", strSQL)
Set qdef = Nothing
Set db = Nothing
End Sub