在没有DataSource的ComboBox上设置DisplayMember和ValueMember

问题描述 投票:2回答:4

我想在DisplayMember上有一个ValueMember和一个ComboBox,它只有4个值,它们总是一样的。

没有使用DataTable作为DataSourceand而不创建一个类是否可能?

我希望有类似的东西:

ValueMember= "Fixed"  
DisplayMember= "Specific and unique number"

ValueMember= "Multiple"  
DisplayMember= "Multiple and different numbers"

ValueMember= "Repeated"  
DisplayMember= "One number repeated x times"
.net vb.net combobox
4个回答
5
投票

从根本上说,你不能做你想做的事:

ValueMember= "Fixed"  
DisplayMember= "Specific and unique number"

Value-DisplayMember不是用于指定文字值,而是用于指示其他内容的属性名称(如类)。


不使用DataSource(标题)与不使用类(问题文本)不同。还有创建类的替代方法:

Existing NET Types

您可以使用现有的NET KeyValuePair类将值与名称链接:

cbox.Items.Add(New KeyValuePair(Of String, String)("Specific", 
         "Specific and unique number"))
cbox.Items.Add(New KeyValuePair(Of String, String)("Multiple", 
         "Multiple and different numbers"))
cbox.Items.Add(New KeyValuePair(Of String, String)("Repeated", 
         "One number repeated x times"))

cbox.ValueMember = "Key"
cbox.DisplayMember = "Value"

没有DataSource - 数据位于items集合中。还有另一个答案中解释的Tuple


Anonymous Type

使用一个字符串作为另一个字符串的键非常奇怪。通常在代码中,您会想要一些不太容易出错的错误。在某处键入“Fized”会破坏您的代码。一个Enum更有意义:

Private Enum ValueStyle
    Specific = 0
    Multiple = 1
    Repeated = 2
End Enum

现在,您可以创建一个List,它链接用户的描述和Enum常量:

' fuller text descr of the enum for the user
Dim descr As String() = {"Specific and unique number",
                         "Multiple and different numbers",
                         "One number repeated x times"}
' get enum values into an array of ValueStyle
Dim values = [Enum].GetValues(GetType(ValueStyle)).Cast(Of ValueStyle).ToArray

' create a List of anon objects from the descr() and values()
Dim lst = values.Select( Function (q) New With
                       {.Value = q, .Name = descr (q)}
                    ).ToList()

cboPicker.ValueMember = "Value"
cboPicker.DisplayMember = "Name"
cboPicker.DataSource = lst

这将创建一个匿名类型 - 一个没有类的对象 - Name和Value属性映射到Enum和description数组。如果Enum值不是连续的(例如{8,65,99}),则必须以不同方式构建列表。

这将创建一个匿名类型对象的临时集合,并将其指定为DataSource。您将无法在其他方法中访问NameValue属性,因为匿名类型无法传递给其他方法。但是用户将看到所需的文本,NET / VB将提供与SelectedValue一样的枚举值。使用SelectedValue更改事件:

' name user sees == cboPicker.Text
' value == cboPicker.SelectedValue boxed as Object

Dim userChoice As ValueStyle = CType(cboPicker.SelectedValue, ValueStyle)
If userChoice = ValueStyle.Specific Then
    '...
ElseIf userChoice = ValueStyle.Repeated Then
    '...
End If

请注意,代码不是将“Fixed”作为字符串进行测试,而是使用枚举,但仍然是可读的。

MSDN:Anonymous Types (Visual Basic)


那些符合不需要新课程的标准,但考虑:

Friend Class NameValuePair
    Public Property Name As String
    Public Property Value As Int32

    Public Sub New(n As String, v As Int32)
        Name = n
        Value = v
    End Sub

    Public Overrides Function ToString() As String
        Return Name
    End Function

End Class

该类非常简单,几乎无限可重复使用任何Name与任何Value。它可以在任意数量的项目中与任意数量的基于列表的控件一起使用。创建和使用它们列表的代码比使用其他方法更简单。


2
投票

使用某个类是一种解决方案,但因为您不想使用自定义类 - 使用内置类型。

Dim values As New List(Of Tuple(Of String, String))()
values.Add(New Tuple("Fixed", "Specific and unique number"))
values.Add(New Tuple("Multiple", "Multiple and different numbers"))
values.Add(New Tuple("Repeated", "One number repeated x times"))
'and so on...

combobox.ValueMember = "Item1"
combobox.DisplayMember = "Item2"
combobox.DataSource = values

Tuple(Of T1, T2) Class

但为了便于阅读,我建议使用自定义类。 或者只是在重用自定义类的情况下比Tuple更好


0
投票

cbActive是一个组合框

Private Sub LoadActiveCB()

    Dim _Active As New List(Of ActiveCB)

    _Active.Add(New ActiveCB With {.Name = "Fixed", .ID = 1})
    _Active.Add(New ActiveCB With {.Name = "Multiple", .ID = 2})
    _Active.Add(New ActiveCB With {.Name = "Repeated", .ID = 3})

    cbActive.DataSource = _Active
    cbActive.DisplayMember = "Name"
    cbActive.ValueMember = "ID"

End Sub

Class ActiveCB
    Property Name As String
    Property ID As Byte
End Class

你需要调整一下,改变显示和价值成员,但我相信这可能是你想要的......?


0
投票

我想我现在得到它......也许是这样的:

Public Class Form1
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim comboSource As New Dictionary(Of String, String)()
        comboSource.Add("1", "Sunday")
        comboSource.Add("2", "Monday")
        comboSource.Add("3", "Tuesday")
        comboSource.Add("4", "Wednesday")
        comboSource.Add("5", "Thursday")
        comboSource.Add("6", "Friday")
        comboSource.Add("7", "Saturday")
        ComboBox1.DataSource = New BindingSource(comboSource, Nothing)
        ComboBox1.DisplayMember = "Value"
        ComboBox1.ValueMember = "Key"
    End Sub
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim key As String = DirectCast(ComboBox1.SelectedItem, KeyValuePair(Of String, String)).Key
        Dim value As String = DirectCast(ComboBox1.SelectedItem, KeyValuePair(Of String, String)).Value
        MessageBox.Show(key & "   " & value)
    End Sub
End Class

图片来源:http://net-informations.com/q/faq/combovalue.html

© www.soinside.com 2019 - 2024. All rights reserved.