编译错误：过程需要太大帮助

Question

我正在处理一个大型Excel项目，该项目需要输入散布在工作表上的大量数据，需要尽快输入这些数据。为了尝试帮助该条目，我创建了许多UserForms，用户可以将数据输入其中。尝试传输数据时，一种这样的形式将返回上述“ Process Too Large”错误。

我理解为什么会弹出错误-太长了。我已经包含了其中一个这样的条目的代码（当然稍作修改），并且想知道如何截断它？

    Dim ws As Worksheet
    Dim i As Long
    Set ws = ThisWorkbook.Sheets("STOCK")

' 101
If entry101.Value <> "" Then
Dim NUM101 As String

If com101.Value <> "" Then
    NUM101 = "# - " & UCase(com101.Value)
Else
    NUM101 = ""
End If

    If cmb101.Value = "FULL" Then
        ws.Range("_101").Value = UCase(code101.Value) & " " & Chr(10) & UCase(com101.Value) & " - FULL " & Chr(10) & " "
    End If
    If cmb101.Value = "OUT OF STOCK" Then
        ws.Range("_101").Value = UCase(com101.Value) & " OUT OF STOCK " & Chr(10) & UCase(code101.Value) & " " & Chr(10) & " "
    End If
    If cmb101.Value = "SHIPPED" Then
        ws.Range("_101").Value = UCase(code101.Value) & " " & Chr(10) & " - SHIPPED " & Chr(10) & NUM101
    End If
    If cmb101.Value = "DAMAGED" Then
        ws.Range("_101").Value = UCase(code101.Value) & " DAMAGED " & Chr(10) & " "" & Chr(10) & NUM101"
    End If
    If cmb101.Value = "LOW STOCK" Then
        ws.Range("_101").Value = UCase(com101.Value) & " LOW-STOCK " & Chr(10) & UCase(code101.Value) & " " & Chr(10) & " "
    End If
    If cmb101.Value = "RETURN" Then
        ws.Range("_101").Value = UCase(code101.Value) & " " & Chr(10) & "RETURNED - " & UCase(com101.Value) & " " & Chr(10) & " "
    End If
    If cmb101.Value = "" Then
        ws.Range("_101").Value = UCase(code101.Value) & Chr(10) & " - UNKNOWN CONDITION"
    End If
End If

UserForm对于每个条目都有两个文本框（“ code101”和“ com101”）和一个组合框（“ cmb101”）。上面的代码需要应用于从“ _101”到“ _143”的范围，因此需要重复43次。

任何帮助将不胜感激。谢谢大家。

Answer 1

这样的东西（未经测试）：

Dim ws As Worksheet, vCom, vCode
Dim i As Long, s, num As String
Set ws = ThisWorkbook.Sheets("STOCK")

For i = 101 To 143
    If Me.Controls("entry" & i).Value <> "" Then

        vCom = UCase(Me.Controls("com" & i).Value)
        vCode = UCase(Me.Controls("code" & i).Value)

        num = IIf(vCom <> "", "# - " & vCom, "")
        s = ""

        Select Case Me.Controls("cmb" & i).Value
            Case "FULL": s = vCode & " " & Chr(10) & vCom & " - FULL " & Chr(10) & " "
            Case "OUT OF STOCK": s = vCom & " OUT OF STOCK " & Chr(10) & vCode & " " & Chr(10) & " "
            Case "SHIPPED": s = vCode & " " & Chr(10) & " - SHIPPED " & Chr(10) & num
            'etc
            'etc
        End Select
        If Len(s) > 0 Then ws.Range("_" & i).Value = s
    End If
Next i