复制多行并粘贴到其他工作表中，跳过 5 行

Question

有人可以帮我写一个vba代码吗。

我必须从工作表 1 中复制一系列单元格并将它们粘贴到工作表 2 中，跳过第 5 行。

特别是复制范围是A1:M45（45行）。范围是固定的

粘贴区域（第 2 页）从

A5:M5

开始，像这样跳过 5 行

1. A5：M5

2. A10：M10

3. A15：M15

4. A20：M20

5. A225：M225

我尝试使用此代码，但无法选择范围，只能选择列，并且无法定义开始/结束单元格。

Sub Test()
    Dim ws1 As Worksheet
    Dim ws2 As Worksheet
    Dim lngRowCounter As Long
    Dim lngRowMultiplier As Long

    lngRowCounter = 1
    lngRowMultiplier = 5

    Set ws1 = Worksheets("Sheet1")
    Set ws2 = Worksheets("Sheet2")

    Do While Not IsEmpty(ws1.Range("A" & lngRowCounter))
        ws2.Range("A" & lngRowCounter * lngRowMultiplier).Value = _
            ws1.Range("A" & lngRowCounter).Value
        lngRowCounter = lngRowCounter + 1
    Loop
End Sub

Answer 1

有很多方法可以实现这一目标。这就是你正在尝试的吗？

Option Explicit

Sub Sample()
    Dim wsA As Worksheet, wsB As Worksheet
    Dim rng As Range
    Dim rw As Long: rw = 5
    Dim i As Long
    
    '~~> Set this to the relevant worksheets
    Set wsA = Sheet1
    Set wsB = Sheet2
    
    With wsA
        For i = 1 To 45
            .Rows(i).Copy wsB.Rows(rw)
            rw = rw + 5
        Next i
    End With
    
    Application.CutCopyMode = False
End Sub