如何在球拍中折叠树形结构？

Question

我有一个可以创建树结构的结构：

(struct node (value left middle right))

和另一个定义叶子节点的结构：

(struct emptyNode ())

我如何制作一个通过将值加在一起将树折叠成一个值的函数，从左子树开始，然后是中间，然后是右？

我正在考虑将树转换为列表，首先是左子树的顺序，然后是中间，然后是右子树的顺序，然后对列表进行折叠，但是不确定如何完成它，或者不确定正确的方法：

(define (treeToList tree)
  (cond
    [(node? tree) (append (node-left tree)) (treeToList (node-left tree))
                  (append (node-middle tree)) (treeToList (node-middle tree))
                  (append (node-right tree)) (treeToList (node-right tree))]
    [else ] ;do nothing, leaf node
    ))

Answer 1

因此，执行此操作的一种好方法是使用Racket的模式匹配。除此之外，使用基于议程的搜索也很不错，这样整个过程都是迭代的。因此，执行求和的函数将具有三个参数：

• 当前节点；
• 需要查看的当前节点议程；
• 运行总数；

然后，它根据与这些参数匹配的模式，循环遍历节点并从议程中推送和弹出内容来决定要做什么。

给定node和empty-node的定义，以及由它们构成的示例树，如下所示：

(struct node (value left middle right))
(struct empty-node ())

(define sample-tree
  (node 1
        (node 2
              (empty-node)
              (node 3 (empty-node) (empty-node) (empty-node))
              (node -1
                    (node 1 (empty-node) (empty-node) (empty-node))
                    (empty-node)
                    (empty-node)))
        (node 10 (empty-node) (empty-node) (empty-node))
        (empty-node)))

我们可以编写一个函数像这样对树求和：

(define (sum-node-tree node-tree)
  (define/match (snt-loop thing agenda sum)
    [((empty-node) '() s)
     ;; an empty node, nothing on the agenda: we're done
     s]
    [((empty-node) (cons next more) s)
     ;; an empty node, but there is an agenda, so start on the next agenda
     ;; item
     (snt-loop next more s)]
    [((node (? number? v) l m r) a s)
     ;; a node with a value: sum the value into the total, push the middle
     ;; and right children onto the agenda, and start on the left child.
     (snt-loop l (list* m r a) (+ s v))]
    [(_ _ _)
     ;; something bad in the tree
     (error 'sum-node-tree "bogus tree")])
  (snt-loop node-tree '() 0))

然后

> (sum-node-tree sample-tree)
16